pkgs/top-level/make-tarball.nix

   1 { nixpkgs
   2 , officialRelease
   3 , pkgs ? import nixpkgs.outPath {}
   4 , nix ? pkgs.nix
   5 , lib-tests ? import ../../lib/tests/release.nix { inherit pkgs; }
   6 }:
   7
   8 pkgs.releaseTools.sourceTarball {
   9   name = "nixpkgs-tarball";
  10   src = nixpkgs;
  11
  12   inherit officialRelease;
  13   version = pkgs.lib.fileContents ../../.version;
  14   versionSuffix = "pre${
  15     if nixpkgs ? lastModified
  16     then builtins.substring 0 8 (nixpkgs.lastModifiedDate or nixpkgs.lastModified)
  17     else toString (nixpkgs.revCount or 0)}.${nixpkgs.shortRev or "dirty"}";
  18
  19   buildInputs = with pkgs; [ nix.out jq lib-tests brotli ];
  20
  21   configurePhase = ''
  22     eval "$preConfigure"
  23     releaseName=nixpkgs-$VERSION$VERSION_SUFFIX
  24     echo -n $VERSION_SUFFIX > .version-suffix
  25     echo -n ${nixpkgs.rev or nixpkgs.shortRev or "dirty"} > .git-revision
  26     echo "release name is $releaseName"
  27     echo "git-revision is $(cat .git-revision)"
  28   '';
  29
  30   dontUnpack = true;
  31
  32   dontBuild = false;
  33
  34   doCheck = true;
  35
  36   checkPhase = ''
  37     echo "generating packages.json"
  38
  39     (
  40       echo -n '{"version":2,"packages":'
  41       NIX_STATE_DIR=$TMPDIR NIX_PATH= nix-env -f $src -qa --meta --json --show-trace --arg config 'import ${./packages-config.nix}'
  42       echo -n '}'
  43     ) | sed "s|$src/||g" | jq -c > packages.json
  44
  45     # Arbitrary number. The index has ~115k packages as of April 2024.
  46     if [ $(jq -r '.packages | length' < packages.json) -lt 100000 ]; then
  47       echo "ERROR: not enough packages in the search index, bailing out!"
  48       exit 1
  49     fi
  50
  51     packages=$out/packages.json.br
  52
  53     mkdir -p $out/nix-support
  54     brotli -9 < packages.json > $packages
  55     echo "file json-br $packages" >> $out/nix-support/hydra-build-products
  56   '';
  57
  58   # --hard-dereference: reproducibility for src if auto-optimise-store = true
  59   #   Some context: https://github.com/NixOS/infra/issues/438
  60   distPhase = ''
  61     mkdir -p $out/tarballs
  62     XZ_OPT="-T0" tar \
  63       --create \
  64       --xz \
  65       --file=$out/tarballs/$releaseName.tar.xz \
  66       --absolute-names \
  67       --transform="s|^$src|$releaseName|g" \
  68       --transform="s|^$(pwd)|$releaseName|g" \
  69       --owner=0 \
  70       --group=0 \
  71       --numeric-owner \
  72       --format=gnu \
  73       --sort=name \
  74       --mtime="@$SOURCE_DATE_EPOCH" \
  75       --mode=ug+w \
  76       --hard-dereference \
  77       $src $(pwd)/{.version-suffix,.git-revision}
  78   '';
  79 }