pkgs/applications/graphics/feh/default.nix

   1 { lib, stdenv, fetchFromGitHub, makeWrapper, fetchpatch
   2 , xorg, imlib2, libjpeg, libpng
   3 , curl, libexif, jpegexiforient, perl
   4 , enableAutoreload ? !stdenv.hostPlatform.isDarwin }:
   5
   6 stdenv.mkDerivation rec {
   7   pname = "feh";
   8   version = "3.10.1";
   9
  10   src = fetchFromGitHub {
  11     owner = "derf";
  12     repo = pname;
  13     rev = version;
  14     hash = "sha256-1dz04RcaoP79EoE+SsatXm2wMRCbNnmAzMECYk3y3jg=";
  15   };
  16
  17   patches = [
  18     # upstream PR: https://github.com/derf/feh/pull/723
  19     (fetchpatch {
  20       name = "fix-right-click-buffer-overflow.patch";
  21       url = "https://github.com/derf/feh/commit/2c31f8863b80030e772a529ade519fc2fee4a991.patch";
  22       sha256 = "sha256-sUWS06qt1d1AyGfqKb+1BzZslYxOzur4q0ePEHcTz1g=";
  23     })
  24   ];
  25
  26   outputs = [ "out" "man" "doc" ];
  27
  28   nativeBuildInputs = [ makeWrapper ];
  29
  30   buildInputs = [ xorg.libXt xorg.libX11 xorg.libXinerama imlib2 libjpeg libpng curl libexif ];
  31
  32   makeFlags = [
  33     "PREFIX=${placeholder "out"}" "exif=1"
  34   ] ++ lib.optional stdenv.isDarwin "verscmp=0"
  35     ++ lib.optional enableAutoreload "inotify=1";
  36
  37   installTargets = [ "install" ];
  38   postInstall = ''
  39     wrapProgram "$out/bin/feh" --prefix PATH : "${lib.makeBinPath [ libjpeg jpegexiforient ]}" \
  40                                --add-flags '--theme=feh'
  41   '';
  42
  43   nativeCheckInputs = lib.singleton (perl.withPackages (p: [ p.TestCommand ]));
  44   doCheck = true;
  45
  46   meta = with lib; {
  47     description = "A light-weight image viewer";
  48     homepage = "https://feh.finalrewind.org/";
  49     # released under a variant of the MIT license
  50     # https://spdx.org/licenses/MIT-feh.html
  51     license = licenses.mit-feh;
  52     maintainers = with maintainers; [ viric willibutz globin ];
  53     platforms = platforms.unix;
  54     mainProgram = "feh";
  55   };
  56 }