pkgs/applications/misc/archivebox/default.nix

   1 { lib
   2 , python3
   3 , fetchFromGitHub
   4 , fetchPypi
   5 }:
   6
   7 let
   8   python = python3.override {
   9     packageOverrides = self: super: {
  10       django = super.django_3.overridePythonAttrs (old: rec {
  11         version = "3.1.14";
  12         src = old.src.override {
  13           inherit version;
  14           hash = "sha256-cqSloTaiFMOc8BbM3Wtp4qoIx0ecZtk/OpteS7nYo0c=";
  15         };
  16         meta = old.meta // {
  17           knownVulnerabilities = [
  18             "CVE-2021-45115"
  19             "CVE-2021-45116"
  20             "CVE-2021-45452"
  21             "CVE-2022-23833"
  22             "CVE-2022-22818"
  23             "CVE-2022-28347"
  24             "CVE-2022-28346"
  25           ];
  26         };
  27       });
  28       django-extensions = super.django-extensions.overridePythonAttrs (old: rec {
  29         version = "3.1.5";
  30         src = fetchFromGitHub {
  31           inherit version;
  32           owner = "django-extensions";
  33           repo = "django-extensions";
  34           rev = "e43f383dae3a35237e42f6acfe1207a8e7e7bdf5";
  35           hash = "sha256-NAMa78KhAuoJfp0Cb0Codz84sRfRQ1JhSLNYRI4GBPM=";
  36         };
  37       });
  38     };
  39   };
  40 in
  41
  42 python.pkgs.buildPythonApplication rec {
  43   pname = "archivebox";
  44   version = "0.6.2";
  45
  46   src = fetchPypi {
  47     inherit pname version;
  48     sha256 = "sha256-zHty7lTra6yab9d0q3EqsPG3F+lrnZL6PjQAbL1A2NY=";
  49   };
  50
  51   propagatedBuildInputs = with python.pkgs; [
  52     requests
  53     mypy-extensions
  54     django
  55     django-extensions
  56     dateparser
  57     youtube-dl
  58     python-crontab
  59     croniter
  60     w3lib
  61     ipython
  62   ];
  63
  64   meta = with lib; {
  65     description = "Open source self-hosted web archiving";
  66     homepage = "https://archivebox.io";
  67     license = licenses.mit;
  68     maintainers = with maintainers; [ siraben ];
  69     platforms = platforms.unix;
  70   };
  71 }