pkgs/applications/misc/parsec/bin.nix

   1 { stdenvNoCC
   2 , stdenv
   3 , lib
   4 , dpkg
   5 , autoPatchelfHook
   6 , makeWrapper
   7 , fetchurl
   8 , alsa-lib
   9 , openssl
  10 , udev
  11 , libglvnd
  12 , libX11
  13 , libXcursor
  14 , libXi
  15 , libXrandr
  16 , libXfixes
  17 , libpulseaudio
  18 , libva
  19 , ffmpeg
  20 , libpng
  21 , libjpeg8
  22 , curl
  23 }:
  24
  25 stdenvNoCC.mkDerivation {
  26   pname = "parsec-bin";
  27   version = "150_86e";
  28
  29   src = fetchurl {
  30     url = "https://web.archive.org/web/20230531105208/https://builds.parsec.app/package/parsec-linux.deb";
  31     sha256 = "sha256-wwBy86TdrHaH9ia40yh24yd5G84WTXREihR+9I6o6uU=";
  32   };
  33
  34   unpackPhase = ''
  35     runHook preUnpack
  36
  37     dpkg-deb -x $src .
  38
  39     runHook postUnpack
  40   '';
  41
  42   nativeBuildInputs = [ dpkg autoPatchelfHook makeWrapper ];
  43
  44   buildInputs = [
  45     stdenv.cc.cc # libstdc++
  46     libglvnd
  47     libX11
  48   ];
  49
  50   runtimeDependenciesPath = lib.makeLibraryPath [
  51     stdenv.cc.cc
  52     libglvnd
  53     openssl
  54     udev
  55     alsa-lib
  56     libpulseaudio
  57     libva
  58     ffmpeg
  59     libpng
  60     libjpeg8
  61     curl
  62     libX11
  63     libXcursor
  64     libXi
  65     libXrandr
  66     libXfixes
  67   ];
  68
  69   prepareParsec = ''
  70     if [[ ! -e "$HOME/.parsec/appdata.json" ]]; then
  71       mkdir -p "$HOME/.parsec"
  72       cp --no-preserve=mode,ownership,timestamps ${placeholder "out"}/share/parsec/skel/* "$HOME/.parsec/"
  73     fi
  74   '';
  75
  76   installPhase = ''
  77     runHook preInstall
  78
  79     mkdir $out
  80     mv usr/* $out
  81
  82     wrapProgram $out/bin/parsecd \
  83       --prefix LD_LIBRARY_PATH : "$runtimeDependenciesPath" \
  84       --run "$prepareParsec"
  85
  86     substituteInPlace $out/share/applications/parsecd.desktop \
  87       --replace "/usr/bin/parsecd" "parsecd" \
  88       --replace "/usr/share/icons" "${placeholder "out"}/share/icons"
  89
  90     runHook postInstall
  91   '';
  92
  93   # Only the main binary needs to be patched, the wrapper script handles
  94   # everything else. The libraries in `share/parsec/skel` would otherwise
  95   # contain dangling references when copied out of the nix store.
  96   dontAutoPatchelf = true;
  97
  98   fixupPhase = ''
  99     runHook preFixup
 100
 101     autoPatchelf $out/bin
 102
 103     runHook postFixup
 104   '';
 105
 106   meta = with lib; {
 107     homepage = "https://parsecgaming.com/";
 108     changelog = "https://parsec.app/changelog";
 109     description = "Remote streaming service client";
 110     license = licenses.unfree;
 111     maintainers = with maintainers; [ arcnmx ];
 112     platforms = platforms.linux;
 113     mainProgram = "parsecd";
 114   };
 115 }