pkgs/applications/misc/pot/default.nix

   1 { lib
   2 , stdenv
   3 , stdenvNoCC
   4 , rustPlatform
   5 , fetchFromGitHub
   6 , wrapGAppsHook
   7 , cargo
   8 , rustc
   9 , cargo-tauri
  10 , pkg-config
  11 , nodePackages
  12 , esbuild
  13 , buildGoModule
  14 , jq
  15 , moreutils
  16 , libayatana-appindicator
  17 , gtk3
  18 , webkitgtk
  19 , libsoup
  20 , openssl
  21 , xdotool
  22 }:
  23
  24 stdenv.mkDerivation rec {
  25   pname = "pot";
  26   version = "2.6.6";
  27
  28   src = fetchFromGitHub {
  29     owner = "pot-app";
  30     repo = "pot-desktop";
  31     rev = version;
  32     hash = "sha256-ZpN+SgBq2vA2p4MjrT07j22VB67FdiXIIl9puGiGJA4=";
  33   };
  34
  35   sourceRoot = "${src.name}/src-tauri";
  36
  37   postPatch = ''
  38     substituteInPlace $cargoDepsCopy/libappindicator-sys-*/src/lib.rs \
  39       --replace "libayatana-appindicator3.so.1" "${libayatana-appindicator}/lib/libayatana-appindicator3.so.1"
  40   '';
  41
  42   pnpm-deps = stdenvNoCC.mkDerivation {
  43     pname = "${pname}-pnpm-deps";
  44     inherit src version;
  45
  46     nativeBuildInputs = [
  47       jq
  48       moreutils
  49       nodePackages.pnpm
  50     ];
  51
  52     installPhase = ''
  53       export HOME=$(mktemp -d)
  54       pnpm config set store-dir $out
  55       # use --ignore-script and --no-optional to avoid downloading binaries
  56       # use --frozen-lockfile to avoid checking git deps
  57       pnpm install --frozen-lockfile --no-optional --ignore-script
  58
  59       # Remove timestamp and sort the json files
  60       rm -rf $out/v3/tmp
  61       for f in $(find $out -name "*.json"); do
  62         sed -i -E -e 's/"checkedAt":[0-9]+,//g' $f
  63         jq --sort-keys . $f | sponge $f
  64       done
  65     '';
  66
  67     dontFixup = true;
  68     outputHashMode = "recursive";
  69     outputHash = "sha256-PqdwoGPsu1j4sDTvBAguDhB2v1yaNWybluLiN37SDa4=";
  70   };
  71
  72   cargoDeps = rustPlatform.importCargoLock {
  73     lockFile = ./Cargo.lock;
  74     outputHashes = {
  75       # All other crates in the same workspace reuse this hash.
  76       "tauri-plugin-autostart-0.0.0" = "sha256-wgVsF3H9BT8lBew7tQ308eIQ6cLZT93hD/4eYCDEq98=";
  77       "tauri-plugin-sql-0.0.0" = "sha256-e9iwcHwW8MaRzkaAbewrq6b9+n3ZofMTBnvA23ZF2ro=";
  78     };
  79   };
  80
  81   nativeBuildInputs = [
  82     rustPlatform.cargoSetupHook
  83     cargo
  84     rustc
  85     cargo-tauri
  86     wrapGAppsHook
  87     nodePackages.pnpm
  88     pkg-config
  89   ];
  90
  91   buildInputs = [
  92     gtk3
  93     libsoup
  94     libayatana-appindicator
  95     openssl
  96     webkitgtk
  97     xdotool
  98   ];
  99
 100   ESBUILD_BINARY_PATH = "${lib.getExe (esbuild.override {
 101     buildGoModule = args: buildGoModule (args // rec {
 102       version = "0.18.20";
 103       src = fetchFromGitHub {
 104         owner = "evanw";
 105         repo = "esbuild";
 106         rev = "v${version}";
 107         hash = "sha256-mED3h+mY+4H465m02ewFK/BgA1i/PQ+ksUNxBlgpUoI=";
 108       };
 109       vendorHash = "sha256-+BfxCyg0KkDQpHt/wycy/8CTG6YBA/VJvJFhhzUnSiQ=";
 110     });
 111   })}";
 112
 113   preBuild = ''
 114     export HOME=$(mktemp -d)
 115     pnpm config set store-dir ${pnpm-deps}
 116     chmod +w ..
 117     pnpm install --offline --frozen-lockfile --no-optional --ignore-script
 118     chmod -R +w ../node_modules
 119     pnpm rebuild
 120     # Use cargo-tauri from nixpkgs instead of pnpm tauri from npm
 121     cargo tauri build -b deb
 122   '';
 123
 124   preInstall = ''
 125     mv target/release/bundle/deb/*/data/usr/ $out
 126   '';
 127
 128   meta = with lib; {
 129     description = "A cross-platform translation software";
 130     homepage = "https://pot.pylogmon.com";
 131     platforms = platforms.linux;
 132     license = licenses.gpl3Only;
 133     maintainers = with maintainers; [ linsui ];
 134   };
 135 }
 136