pkgs/applications/misc/prusa-slicer/default.nix

   1 { stdenv
   2 , lib
   3 , openexr
   4 , jemalloc
   5 , c-blosc
   6 , binutils
   7 , fetchFromGitHub
   8 , cmake
   9 , pkg-config
  10 , wrapGAppsHook
  11 , boost
  12 , cereal
  13 , cgal_5
  14 , curl
  15 , dbus
  16 , eigen
  17 , expat
  18 , glew
  19 , glib
  20 , gmp
  21 , gtk3
  22 , hicolor-icon-theme
  23 , ilmbase
  24 , libpng
  25 , mpfr
  26 , nanosvg
  27 , nlopt
  28 , opencascade-occt
  29 , openvdb
  30 , pcre
  31 , qhull
  32 , tbb_2021_8
  33 , wxGTK32
  34 , xorg
  35 , fetchpatch
  36 , withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd, systemd
  37 , wxGTK-override ? null
  38 }:
  39 let
  40   wxGTK-prusa = wxGTK32.overrideAttrs (old: rec {
  41     pname = "wxwidgets-prusa3d-patched";
  42     version = "3.2.0";
  43     configureFlags = old.configureFlags ++ [ "--disable-glcanvasegl" ];
  44     patches = [ ./wxWidgets-Makefile.in-fix.patch ];
  45     src = fetchFromGitHub {
  46       owner = "prusa3d";
  47       repo = "wxWidgets";
  48       rev = "78aa2dc0ea7ce99dc19adc1140f74c3e2e3f3a26";
  49       hash = "sha256-rYvmNmvv48JSKVT4ph9AS+JdstnLSRmcpWz1IdgBzQo=";
  50       fetchSubmodules = true;
  51     };
  52   });
  53   nanosvg-fltk = nanosvg.overrideAttrs (old: rec {
  54     pname = "nanosvg-fltk";
  55     version = "unstable-2022-12-22";
  56
  57     src = fetchFromGitHub {
  58       owner = "fltk";
  59       repo = "nanosvg";
  60       rev = "abcd277ea45e9098bed752cf9c6875b533c0892f";
  61       hash = "sha256-WNdAYu66ggpSYJ8Kt57yEA4mSTv+Rvzj9Rm1q765HpY=";
  62     };
  63   });
  64   openvdb_tbb_2021_8 = openvdb.overrideAttrs (old: rec {
  65     buildInputs = [ openexr boost tbb_2021_8 jemalloc c-blosc ilmbase ];
  66   });
  67   wxGTK-override' = if wxGTK-override == null then wxGTK-prusa else wxGTK-override;
  68 in
  69 stdenv.mkDerivation (finalAttrs: {
  70   pname = "prusa-slicer";
  71   version = "2.6.1";
  72
  73   nativeBuildInputs = [
  74     cmake
  75     pkg-config
  76     wrapGAppsHook
  77   ];
  78
  79   buildInputs = [
  80     binutils
  81     boost
  82     cereal
  83     cgal_5
  84     curl
  85     dbus
  86     eigen
  87     expat
  88     glew
  89     glib
  90     gmp
  91     gtk3
  92     hicolor-icon-theme
  93     ilmbase
  94     libpng
  95     mpfr
  96     nanosvg-fltk
  97     nlopt
  98     opencascade-occt
  99     openvdb_tbb_2021_8
 100     pcre
 101     qhull
 102     tbb_2021_8
 103     wxGTK-override'
 104     xorg.libX11
 105   ] ++ lib.optionals withSystemd [
 106     systemd
 107   ];
 108
 109   separateDebugInfo = true;
 110
 111   # The build system uses custom logic - defined in
 112   # cmake/modules/FindNLopt.cmake in the package source - for finding the nlopt
 113   # library, which doesn't pick up the package in the nix store.  We
 114   # additionally need to set the path via the NLOPT environment variable.
 115   NLOPT = nlopt;
 116
 117   # prusa-slicer uses dlopen on `libudev.so` at runtime
 118   NIX_LDFLAGS = lib.optionalString withSystemd "-ludev";
 119
 120   prePatch = ''
 121     # Since version 2.5.0 of nlopt we need to link to libnlopt, as libnlopt_cxx
 122     # now seems to be integrated into the main lib.
 123     sed -i 's|nlopt_cxx|nlopt|g' cmake/modules/FindNLopt.cmake
 124
 125     # Disable slic3r_jobs_tests.cpp as the test fails sometimes
 126     sed -i 's|slic3r_jobs_tests.cpp||g' tests/slic3rutils/CMakeLists.txt
 127
 128     # prusa-slicer expects the OCCTWrapper shared library in the same folder as
 129     # the executable when loading STEP files. We force the loader to find it in
 130     # the usual locations (i.e. LD_LIBRARY_PATH) instead. See the manpage
 131     # dlopen(3) for context.
 132     if [ -f "src/libslic3r/Format/STEP.cpp" ]; then
 133       substituteInPlace src/libslic3r/Format/STEP.cpp \
 134         --replace 'libpath /= "OCCTWrapper.so";' 'libpath = "OCCTWrapper.so";'
 135     fi
 136     # https://github.com/prusa3d/PrusaSlicer/issues/9581
 137     if [ -f "cmake/modules/FindEXPAT.cmake" ]; then
 138       rm cmake/modules/FindEXPAT.cmake
 139     fi
 140
 141     # Fix resources folder location on macOS
 142     substituteInPlace src/PrusaSlicer.cpp \
 143       --replace "#ifdef __APPLE__" "#if 0"
 144   '';
 145
 146   patches = [
 147     # wxWidgets: CheckResizerFlags assert fix
 148     (fetchpatch {
 149       url = "https://github.com/prusa3d/PrusaSlicer/commit/24a5ebd65c9d25a0fd69a3716d079fd1b00eb15c.patch";
 150       hash = "sha256-MNGtaI7THu6HEl9dMwcO1hkrCtIkscoNh4ulA2cKtZA=";
 151     })
 152   ];
 153
 154   src = fetchFromGitHub {
 155     owner = "prusa3d";
 156     repo = "PrusaSlicer";
 157     hash = "sha256-t5lnBL7SZVfyR680ZK29YXgE3pag+uVv4+BGJZq40/A=";
 158     rev = "version_${finalAttrs.version}";
 159   };
 160
 161   cmakeFlags = [
 162     "-DSLIC3R_STATIC=0"
 163     "-DSLIC3R_FHS=1"
 164     "-DSLIC3R_GTK=3"
 165   ];
 166
 167   postInstall = ''
 168     ln -s "$out/bin/prusa-slicer" "$out/bin/prusa-gcodeviewer"
 169
 170     mkdir -p "$out/lib"
 171     mv -v $out/bin/*.* $out/lib/
 172
 173     mkdir -p "$out/share/pixmaps/"
 174     ln -s "$out/share/PrusaSlicer/icons/PrusaSlicer.png" "$out/share/pixmaps/PrusaSlicer.png"
 175     ln -s "$out/share/PrusaSlicer/icons/PrusaSlicer-gcodeviewer_192px.png" "$out/share/pixmaps/PrusaSlicer-gcodeviewer.png"
 176   '';
 177
 178   preFixup = ''
 179     gappsWrapperArgs+=(
 180       --prefix LD_LIBRARY_PATH : "$out/lib"
 181     )
 182   '';
 183
 184   doCheck = true;
 185
 186   checkPhase = ''
 187     runHook preCheck
 188
 189     ctest \
 190       --force-new-ctest-process \
 191       -E 'libslic3r_tests|sla_print_tests'
 192
 193     runHook postCheck
 194   '';
 195
 196   meta = with lib; {
 197     description = "G-code generator for 3D printer";
 198     homepage = "https://github.com/prusa3d/PrusaSlicer";
 199     license = licenses.agpl3;
 200     maintainers = with maintainers; [ moredread tweber tmarkus ];
 201   } // lib.optionalAttrs (stdenv.isDarwin) {
 202     mainProgram = "PrusaSlicer";
 203   };
 204 })