pkgs/applications/misc/sweethome3d/editors.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , makeWrapper
   5 , makeDesktopItem
   6 # sweethome3d 6.5.2 does not yet fully build&run with jdk 9 and later?
   7 , jdk8
   8 , jre8
   9 , ant
  10 , gtk3
  11 , gsettings-desktop-schemas
  12 , sweethome3dApp
  13 , unzip
  14 }:
  15
  16 let
  17
  18   sweetExec = with lib;
  19     m: "sweethome3d-"
  20     + removeSuffix "libraryeditor" (toLower m)
  21     + "-editor";
  22
  23   applicationSrc = stdenv.mkDerivation {
  24     name = "application-src";
  25     src = sweethome3dApp.src;
  26     nativeBuildInputs = [ unzip ];
  27     buildPhase = "";
  28     installPhase = "cp -r . $out";
  29   };
  30
  31   mkEditorProject =
  32   { pname, module, version, src, license, description, desktopName }:
  33
  34   stdenv.mkDerivation rec {
  35     application = sweethome3dApp;
  36     inherit pname module version src description;
  37     exec = sweetExec module;
  38     editorItem = makeDesktopItem {
  39       inherit exec desktopName;
  40       name = pname;
  41       comment =  description;
  42       genericName = "Computer Aided (Interior) Design";
  43       categories = [ "Graphics" "2DGraphics" "3DGraphics" ];
  44     };
  45
  46     nativeBuildInputs = [ makeWrapper unzip ];
  47     buildInputs = [ ant jre8 jdk8 gtk3 gsettings-desktop-schemas ];
  48
  49     postPatch = ''
  50       sed -i -e 's,../SweetHome3D,${applicationSrc},g' build.xml
  51       sed -i -e 's,lib/macosx/java3d-1.6/jogl-all.jar,lib/java3d-1.6/jogl-all.jar,g' build.xml
  52     '';
  53
  54     buildPhase = ''
  55       runHook preBuild
  56
  57       ant -lib ${applicationSrc}/libtest -lib ${applicationSrc}/lib -lib ${jdk8}/lib
  58
  59       runHook postBuild
  60     '';
  61
  62     installPhase = ''
  63       mkdir -p $out/bin
  64       mkdir -p $out/share/{java,applications}
  65       cp ${module}-${version}.jar $out/share/java/.
  66       cp "${editorItem}/share/applications/"* $out/share/applications
  67       makeWrapper ${jre8}/bin/java $out/bin/$exec \
  68         --prefix XDG_DATA_DIRS : "$XDG_ICON_DIRS:${gtk3.out}/share:${gsettings-desktop-schemas}/share:$out/share:$GSETTINGS_SCHEMAS_PATH" \
  69         --add-flags "-jar $out/share/java/${module}-${version}.jar -d${toString stdenv.hostPlatform.parsed.cpu.bits}"
  70     '';
  71
  72     dontStrip = true;
  73
  74     meta = {
  75       homepage = "http://www.sweethome3d.com/index.jsp";
  76       inherit description;
  77       inherit license;
  78       maintainers = [ lib.maintainers.edwtjo ];
  79       platforms = lib.platforms.linux;
  80     };
  81
  82   };
  83
  84   d2u = lib.replaceStrings ["."] ["_"];
  85
  86 in {
  87
  88   textures-editor = mkEditorProject rec {
  89     version = "1.7";
  90     module = "TexturesLibraryEditor";
  91     pname = module;
  92     description = "Easily create SH3T files and edit the properties of the texture images it contain";
  93     license = lib.licenses.gpl2Plus;
  94     src = fetchurl {
  95       url = "mirror://sourceforge/sweethome3d/${module}-${version}-src.zip";
  96       sha256 = "03vb9y645qzffxxdhgbjb0d98k3lafxckg2vh2s86j62b6357d0h";
  97     };
  98     desktopName = "Sweet Home 3D - Textures Library Editor";
  99   };
 100
 101   furniture-editor = mkEditorProject rec {
 102     version = "1.28";
 103     module = "FurnitureLibraryEditor";
 104     pname = module;
 105     description = "Quickly create SH3F files and edit the properties of the 3D models it contain";
 106     license = lib.licenses.gpl2;
 107     src = fetchurl {
 108       url = "mirror://sourceforge/sweethome3d/${module}-${version}-src.zip";
 109       sha256 = "sha256-r5xJlUctUdcknJfm8rbz+bdzFhqgHsHpHwxEC4mItws=";
 110     };
 111     desktopName = "Sweet Home 3D - Furniture Library Editor";
 112   };
 113
 114 }