pkgs/applications/video/kmplayer/default.nix

   1 {
   2   mkDerivation, lib, fetchurl,
   3   extra-cmake-modules, makeWrapper,
   4   libpthreadstubs, libXdmcp,
   5   qtsvg, qtx11extras, ki18n, kdelibs4support, kio, kmediaplayer, kwidgetsaddons,
   6   phonon, cairo, mplayer
   7 }:
   8
   9 mkDerivation rec {
  10   majorMinorVersion = "0.12";
  11   patchVersion = "0b";
  12   version = "${majorMinorVersion}.${patchVersion}";
  13   pname = "kmplayer";
  14
  15   src = fetchurl {
  16     url = "mirror://kde/stable/kmplayer/${majorMinorVersion}/kmplayer-${version}.tar.bz2";
  17     sha256 = "0wzdxym4fc83wvqyhcwid65yv59a2wvp1lq303cn124mpnlwx62y";
  18   };
  19
  20   patches = [
  21     ./kmplayer_part-plugin_metadata.patch # Qt 5.9 doesn't like an empty string for the optional "FILE" argument of "Q_PLUGIN_METADATA"
  22     ./no-docs.patch # Don't build docs due to errors (kdelibs4support propagates kdoctools)
  23   ];
  24
  25   postPatch = ''
  26     sed -i src/kmplayer.desktop \
  27       -e "s,^Exec.*,Exec=$out/bin/kmplayer -qwindowtitle %c %i %U,"
  28   '';
  29
  30   # required for kf5auth to work correctly
  31   cmakeFlags = ["-DCMAKE_POLICY_DEFAULT_CMP0012=NEW"];
  32
  33   nativeBuildInputs = [ extra-cmake-modules makeWrapper ];
  34
  35   buildInputs = [
  36     libpthreadstubs libXdmcp
  37     qtsvg qtx11extras ki18n kdelibs4support kio kmediaplayer kwidgetsaddons
  38     phonon cairo
  39   ];
  40
  41   postInstall = ''
  42     wrapProgram $out/bin/kmplayer --suffix PATH : ${mplayer}/bin
  43   '';
  44
  45   meta = with lib; {
  46     description = "MPlayer front-end for KDE";
  47     license = with licenses; [ gpl2Plus lgpl2Plus fdl12Plus ];
  48     homepage = "https://kmplayer.kde.org/";
  49     maintainers = with maintainers; [ sander zraexy ];
  50   };
  51 }