pkgs/applications/video/vdr/plugins.nix

   1 { lib, stdenv, vdr, fetchFromGitHub
   2 , graphicsmagick, pcre
   3 , boost, libgcrypt, perl, util-linux, groff, ncurses
   4 , callPackage
   5 }: let
   6   mkPlugin = name: stdenv.mkDerivation {
   7     name = "vdr-${name}-${vdr.version}";
   8     inherit (vdr) src;
   9     buildInputs = [ vdr ];
  10     preConfigure = "cd PLUGINS/src/${name}";
  11     installFlags = [ "DESTDIR=$(out)" ];
  12   };
  13 in {
  14
  15   markad = callPackage ./markad {};
  16
  17   nopacity = callPackage ./nopacity {};
  18
  19   softhddevice = callPackage ./softhddevice {};
  20
  21   streamdev = callPackage ./streamdev {};
  22
  23   xineliboutput = callPackage ./xineliboutput {};
  24
  25   skincurses = (mkPlugin "skincurses").overrideAttrs(oldAttr: {
  26     buildInputs = oldAttr.buildInputs ++ [ ncurses ];
  27   });
  28
  29   inherit (lib.genAttrs [
  30     "epgtableid0" "hello" "osddemo" "pictures" "servicedemo" "status" "svdrpdemo"
  31   ] mkPlugin);
  32
  33   femon = stdenv.mkDerivation rec {
  34     pname = "vdr-femon";
  35     version = "2.4.0";
  36
  37     buildInputs = [ vdr ];
  38
  39     src = fetchFromGitHub {
  40       repo = "vdr-plugin-femon";
  41       owner = "rofafor";
  42       sha256 = "sha256-0qBMYgNKk7N9Bj8fAoOokUo+G9gfj16N5e7dhoKRBqs=";
  43       rev = "v${version}";
  44     };
  45
  46     postPatch = "substituteInPlace Makefile --replace /bin/true true";
  47
  48     makeFlags = [ "DESTDIR=$(out)" ];
  49
  50     meta = with lib; {
  51       inherit (src.meta) homepage;
  52       description = "DVB Frontend Status Monitor plugin for VDR";
  53       maintainers = [ maintainers.ck3d ];
  54       license = licenses.gpl2;
  55       inherit (vdr.meta) platforms;
  56     };
  57
  58   };
  59
  60   epgsearch = stdenv.mkDerivation rec {
  61     pname = "vdr-epgsearch";
  62     version = "2.4.2";
  63
  64     src = fetchFromGitHub {
  65       repo = "vdr-plugin-epgsearch";
  66       owner = "vdr-projects";
  67       sha256 = "sha256-C+WSdGTnDBTWLvpjG5GBaK8pYbht431nL5iaL/a0H4Y=";
  68       rev = "v${version}";
  69     };
  70
  71     postPatch = ''
  72       for f in *.sh; do
  73         patchShebangs "$f"
  74       done
  75     '';
  76
  77     nativeBuildInputs = [
  78       perl # for pod2man and pos2html
  79       util-linux
  80       groff
  81     ];
  82
  83     buildInputs = [
  84       vdr
  85       pcre
  86     ];
  87
  88     buildFlags = [
  89       "SENDMAIL="
  90       "REGEXLIB=pcre"
  91     ];
  92
  93     installFlags = [
  94       "DESTDIR=$(out)"
  95     ];
  96
  97     outputs = [ "out" "man" ];
  98
  99     meta = with lib; {
 100       inherit (src.meta) homepage;
 101       description = "Searchtimer and replacement of the VDR program menu";
 102       maintainers = [ maintainers.ck3d ];
 103       license = licenses.gpl2;
 104       inherit (vdr.meta) platforms;
 105     };
 106
 107   };
 108
 109   vnsiserver = stdenv.mkDerivation rec {
 110     pname = "vdr-vnsiserver";
 111     version = "1.8.3";
 112
 113     buildInputs = [ vdr ];
 114
 115     installFlags = [ "DESTDIR=$(out)" ];
 116
 117     src = fetchFromGitHub {
 118       repo = "vdr-plugin-vnsiserver";
 119       owner = "vdr-projects";
 120       rev = version;
 121       sha256 = "sha256-ivHdzX90ozMXSvIc5OrKC5qHeK5W3TK8zyrN8mY3IhE=";
 122     };
 123
 124     meta = with lib; {
 125       inherit (src.meta) homepage;
 126       description = "VDR plugin to handle KODI clients.";
 127       maintainers = [ maintainers.ck3d ];
 128       license = licenses.gpl2;
 129       inherit (vdr.meta) platforms;
 130     };
 131
 132   };
 133
 134   text2skin = stdenv.mkDerivation rec {
 135     pname = "vdr-text2skin";
 136     version = "1.3.4-20170702";
 137
 138     src = fetchFromGitHub {
 139       repo = "vdr-plugin-text2skin";
 140       owner = "vdr-projects";
 141       rev = "8f7954da2488ced734c30e7c2704b92a44e6e1ad";
 142       sha256 = "19hkwmaw6nwak38bv6cm2vcjjkf4w5yjyxb98qq6zfjjh5wq54aa";
 143     };
 144
 145     buildInputs = [ vdr graphicsmagick ];
 146
 147     buildFlags = [
 148       "DESTDIR=$(out)"
 149       "IMAGELIB=graphicsmagic"
 150       "VDRDIR=${vdr.dev}/include/vdr"
 151       "LOCALEDIR=$(DESTDIR)/share/locale"
 152       "LIBDIR=$(DESTDIR)/lib/vdr"
 153     ];
 154
 155     preBuild = ''
 156       mkdir -p $out/lib/vdr
 157     '';
 158
 159     dontInstall = true;
 160
 161     meta = with lib; {
 162       inherit (src.meta) homepage;
 163       description = "VDR Text2Skin Plugin";
 164       maintainers = [ maintainers.ck3d ];
 165       license = licenses.gpl2;
 166       inherit (vdr.meta) platforms;
 167     };
 168   };
 169
 170   fritzbox = stdenv.mkDerivation rec {
 171     pname = "vdr-fritzbox";
 172     version = "1.5.4";
 173
 174     src = fetchFromGitHub {
 175       owner = "jowi24";
 176       repo = "vdr-fritz";
 177       rev = version;
 178       sha256 = "sha256-DGD73i+ZHFgtCo+pMj5JaMovvb5vS1x20hmc5t29//o=";
 179       fetchSubmodules = true;
 180     };
 181
 182     buildInputs = [ vdr boost libgcrypt ];
 183
 184     installFlags = [ "DESTDIR=$(out)" ];
 185
 186     meta = with lib; {
 187       inherit (src.meta) homepage;
 188       description = "A plugin for VDR to access AVMs Fritz Box routers";
 189       maintainers = [ maintainers.ck3d ];
 190       license = licenses.gpl2;
 191       inherit (vdr.meta) platforms;
 192     };
 193   };
 194 }