pkgs/applications/virtualization/qtemu/default.nix

   1 { lib, mkDerivation, fetchFromGitLab, pkg-config, qmake, qtbase, qemu }:
   2
   3 mkDerivation rec {
   4   pname = "qtemu";
   5   version = "2.1";
   6
   7   src = fetchFromGitLab {
   8     owner = "qtemu";
   9     repo = "gui";
  10     rev = version;
  11     sha256 = "1555178mkfw0gwmw8bsxmg4339j2ifp0yb4b2f39nxh9hwshg07j";
  12   };
  13
  14   nativeBuildInputs = [
  15     qmake
  16     pkg-config
  17   ];
  18
  19   buildInputs = [
  20     qtbase
  21     qemu
  22   ];
  23
  24   installPhase = ''
  25     runHook preInstall
  26
  27     # upstream lacks an install method
  28     install -D -t $out/share/applications qtemu.desktop
  29     install -D -t $out/share/pixmaps qtemu.png
  30     install -D -t $out/bin qtemu
  31
  32     # make sure that the qemu-* executables are found
  33     wrapProgram $out/bin/qtemu --prefix PATH : ${lib.makeBinPath [ qemu ]}
  34
  35     runHook postInstall
  36   '';
  37
  38   meta = with lib; {
  39     description = "Qt-based front-end for QEMU emulator";
  40     homepage = "https://qtemu.org";
  41     license = licenses.gpl2;
  42     platforms = with platforms; linux;
  43     maintainers = with maintainers; [ romildo ];
  44   };
  45 }