pkgs/applications/window-managers/openbox/default.nix

   1 { lib, stdenv, fetchurl, fetchpatch, autoreconfHook, pkg-config, python3
   2 , libxml2, libXinerama, libXcursor, libXau, libXrandr, libICE, libSM
   3 , imlib2, pango, libstartup_notification, makeWrapper }:
   4
   5 stdenv.mkDerivation rec {
   6   pname = "openbox";
   7   version = "3.6.1";
   8
   9   nativeBuildInputs = [
  10     autoreconfHook
  11     pkg-config
  12     makeWrapper
  13     python3.pkgs.wrapPython
  14   ];
  15
  16   buildInputs = [
  17     libxml2
  18     libXinerama libXcursor libXau libXrandr libICE libSM
  19     libstartup_notification
  20     python3
  21   ];
  22
  23   propagatedBuildInputs = [
  24     pango imlib2
  25   ];
  26
  27   pythonPath = with python3.pkgs; [
  28     pyxdg
  29   ];
  30
  31   src = fetchurl {
  32     url = "http://openbox.org/dist/openbox/${pname}-${version}.tar.gz";
  33     sha256 = "1xvyvqxlhy08n61rjkckmrzah2si1i7nmc7s8h07riqq01vc0jlb";
  34   };
  35
  36   setlayoutSrc = fetchurl {
  37     url = "http://openbox.org/dist/tools/setlayout.c";
  38     sha256 = "1ci9lq4qqhl31yz1jwwjiawah0f7x0vx44ap8baw7r6rdi00pyiv";
  39   };
  40
  41   patches = [
  42     # Use fetchurl to avoid "fetchpatch: ignores file renames" #32084
  43     # This patch adds python3 support
  44     (fetchurl {
  45       url = "https://raw.githubusercontent.com/archlinux/svntogit-community/90cb57ef53d952bb6ab4c33a184f815bbe1791c0/openbox/trunk/py3.patch";
  46       sha256 = "1ks99awlkhd5ph9kz94s1r6m1bfvh42g4rmxd14dyg5b421p1ljc";
  47     })
  48
  49     # Fix crash with GLib 2.76. This is proposed on https://bugzilla.icculus.org/show_bug.cgi?id=6669
  50     # and commited to a work branch in the upstream repo. See https://bugs.archlinux.org/task/77853.
  51     (fetchpatch {
  52       url = "https://github.com/Mikachu/openbox/commit/d41128e5a1002af41c976c8860f8299cfcd3cd72.patch";
  53       sha256 = "sha256-4/aoI4y98JPybZ1MNI7egOhkroQgh/oeGnYrhNGX4t4=";
  54     })
  55   ];
  56
  57   postBuild = "gcc -O2 -o setlayout $(pkg-config --cflags --libs x11) $setlayoutSrc";
  58
  59   # Openbox needs XDG_DATA_DIRS set or it can't find its default theme
  60   postInstall = ''
  61     cp -a setlayout "$out"/bin
  62     wrapProgram "$out/bin/openbox" --prefix XDG_DATA_DIRS : "$out/share"
  63     wrapProgram "$out/bin/openbox-session" --prefix XDG_DATA_DIRS : "$out/share"
  64     wrapProgram "$out/bin/openbox-gnome-session" --prefix XDG_DATA_DIRS : "$out/share"
  65     wrapProgram "$out/bin/openbox-kde-session" --prefix XDG_DATA_DIRS : "$out/share"
  66     wrapPythonProgramsIn "$out/libexec" "$out $pythonPath"
  67   '';
  68
  69   meta = {
  70     description = "X window manager for non-desktop embedded systems";
  71     homepage = "http://openbox.org/";
  72     license = lib.licenses.gpl2Plus;
  73     platforms = lib.platforms.linux;
  74   };
  75 }