pkgs/by-name/bm/bmake/package.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , fetchpatch
   5 , getopt
   6 , ksh
   7 , bc
   8 , tzdata
   9 , pkgsMusl # for passthru.tests
  10 }:
  11
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "bmake";
  14   version = "20230909";
  15
  16   src = fetchurl {
  17     url = "http://www.crufty.net/ftp/pub/sjg/bmake-${finalAttrs.version}.tar.gz";
  18     hash = "sha256-Hl5sdlQN/oEEQmzX/T9xXMZAT5A5ySA0RwErjy9re4Y=";
  19   };
  20
  21   patches = [
  22     # make bootstrap script aware of the prefix in /nix/store
  23     ./001-bootstrap-fix.diff
  24     # decouple tests from build phase
  25     ./002-dont-test-while-installing.diff
  26     # preserve PATH from build env in unit tests
  27     ./003-fix-unexport-env-test.diff
  28     # Always enable ksh test since it checks in a impure location /bin/ksh
  29     ./004-unconditional-ksh-test.diff
  30   ];
  31
  32   # Make tests work with musl
  33   # * Disable deptgt-delete_on_error test (alpine does this too)
  34   # * Disable shell-ksh test (ksh doesn't compile with musl)
  35   # * Fix test failing due to different strerror(3) output for musl and glibc
  36   postPatch = lib.optionalString (stdenv.hostPlatform.libc == "musl") ''
  37     sed -i unit-tests/Makefile \
  38       -e '/deptgt-delete_on_error/d' \
  39       -e '/shell-ksh/d'
  40     substituteInPlace unit-tests/opt-chdir.exp --replace "File name" "Filename"
  41   '';
  42
  43   nativeBuildInputs = [ getopt ];
  44
  45   # The generated makefile is a small wrapper for calling ./boot-strap with a
  46   # given op. On a case-insensitive filesystem this generated makefile clobbers
  47   # a distinct, shipped, Makefile and causes infinite recursion during tests
  48   # which eventually fail with "fork: Resource temporarily unavailable"
  49   configureFlags = [
  50     "--without-makefile"
  51   ];
  52
  53   buildPhase = ''
  54     runHook preBuild
  55
  56     ./boot-strap --prefix=$out -o . op=build
  57
  58     runHook postBuild
  59   '';
  60
  61   installPhase = ''
  62     runHook preInstall
  63
  64     ./boot-strap --prefix=$out -o . op=install
  65
  66     runHook postInstall
  67   '';
  68
  69   doCheck = true;
  70
  71   nativeCheckInputs = [
  72     bc
  73     tzdata
  74   ] ++ lib.optionals (stdenv.hostPlatform.libc != "musl") [
  75     ksh
  76   ];
  77
  78   # Disabled tests:
  79   # directive-export{,-gmake}: another failure related to TZ variables
  80   # opt-chdir: ofborg complains about it somehow
  81   # opt-keep-going-indirect: not yet known
  82   # varmod-localtime: musl doesn't support TZDIR and this test relies on impure,
  83   # implicit paths
  84   env.BROKEN_TESTS = builtins.concatStringsSep " " [
  85     "directive-export"
  86     "directive-export-gmake"
  87     "opt-chdir" # works on my machine -- AndersonTorres
  88     "opt-keep-going-indirect"
  89     "varmod-localtime"
  90   ];
  91
  92   checkPhase = ''
  93     runHook preCheck
  94
  95     ./boot-strap -o . op=test
  96
  97     runHook postCheck
  98   '';
  99
 100   strictDeps = true;
 101
 102   setupHook = ./setup-hook.sh;
 103
 104   passthru.tests.bmakeMusl = pkgsMusl.bmake;
 105
 106   meta = {
 107     homepage = "http://www.crufty.net/help/sjg/bmake.html";
 108     description = "Portable version of NetBSD 'make'";
 109     license = lib.licenses.bsd3;
 110     mainProgram = "bmake";
 111     maintainers = with lib.maintainers; [ thoughtpolice AndersonTorres ];
 112     platforms = lib.platforms.unix;
 113     # ofborg: x86_64-linux builds the musl package, aarch64-linux doesn't
 114     broken = stdenv.hostPlatform.isMusl && stdenv.buildPlatform.isAarch64;
 115   };
 116 })
 117 # TODO: report the quirks and patches to bmake devteam (especially the Musl one)
 118 # TODO: investigate Musl support