pkgs/by-name/en/engage/package.nix

   1 { lib
   2 , installShellFiles
   3 , rustPlatform
   4 , fetchgit
   5 }:
   6
   7 let
   8   pname = "engage";
   9   version = "0.2.0";
  10 in
  11 rustPlatform.buildRustPackage {
  12   inherit pname version;
  13
  14   # fetchFromGitLab doesn't work on GitLab's end for unknown reasons
  15   src = fetchgit {
  16     url = "https://or.computer.surgery/charles/${pname}";
  17     rev = "v${version}";
  18     hash = "sha256-niXh63xTpXSp9Wqwfi8hUBKJSClOUSvB+TPCTaqHfZk=";
  19   };
  20
  21   cargoHash = "sha256-CKe0nb5JHi5+1UlVOl01Q3qSXQLlpEBdat/IzRKfaz0=";
  22
  23   nativeBuildInputs = [
  24     installShellFiles
  25   ];
  26
  27   postInstall = "installShellCompletion --cmd ${pname} "
  28     + builtins.concatStringsSep
  29       " "
  30       (builtins.map
  31         (shell: "--${shell} <($out/bin/${pname} completions ${shell})")
  32         [
  33           "bash"
  34           "fish"
  35           "zsh"
  36         ]
  37       );
  38
  39   meta = {
  40     description = "A task runner with DAG-based parallelism";
  41     homepage = "https://or.computer.surgery/charles/engage";
  42     changelog = "https://or.computer.surgery/charles/engage/-/blob/v${version}/CHANGELOG.md";
  43     license = with lib.licenses; [ asl20 mit ];
  44     maintainers = with lib.maintainers; [ CobaltCause ];
  45   };
  46 }