pkgs/by-name/te/tecoc/package.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , ncurses
   5 , unstableGitUpdater
   6 }:
   7
   8 stdenv.mkDerivation (finalAttrs: {
   9   pname = "tecoc";
  10   version = "unstable-2023-06-21";
  11
  12   src = fetchFromGitHub {
  13     owner = "blakemcbride";
  14     repo = "TECOC";
  15     rev = "b4a96395a18c7e64ccaef0e25fdde3b7ef33ac4b";
  16     hash = "sha256-KTOGsTtxJh2sneU2VoDNUHcL3m8zt+3rBZTDvK1n02A=";
  17   };
  18
  19   buildInputs = [ ncurses ];
  20
  21   makefile = if stdenv.hostPlatform.isDarwin
  22              then "makefile.osx"
  23              else if stdenv.hostPlatform.isFreeBSD
  24              then "makefile.bsd"
  25              else if stdenv.hostPlatform.isOpenBSD
  26              then "makefile.bsd"
  27              else if stdenv.hostPlatform.isWindows
  28              then "makefile.win"
  29              else "makefile.linux"; # I think Linux is a safe default...
  30
  31   makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" "-C src/" ];
  32
  33   installPhase = ''
  34     runHook preInstall
  35
  36     install -d $out/bin $out/share/doc/tecoc $out/lib/teco/macros
  37     install -m755 src/tecoc $out/bin
  38     install -m644 src/aaout.txt doc/* $out/share/doc/tecoc
  39     install -m644 lib/* lib2/* $out/lib/teco/macros
  40
  41     runHook postInstall
  42   '';
  43
  44   postFixup = ''
  45     pushd $out/bin
  46     ln -s tecoc Make
  47     ln -s tecoc mung
  48     ln -s tecoc teco
  49     ln -s tecoc Inspect
  50     popd
  51   '';
  52
  53   passthru.updateScript = unstableGitUpdater {
  54     url = finalAttrs.meta.homepage;
  55   };
  56
  57   meta = {
  58     homepage = "https://github.com/blakemcbride/TECOC";
  59     description = "A clone of the good old TECO editor";
  60     longDescription = ''
  61       For those who don't know: TECO is the acronym of Tape Editor and COrrector
  62       (because it was a paper tape edition tool in its debut days). Now the
  63       acronym follows after Text Editor and Corrector, or Text Editor
  64       Character-Oriented.
  65
  66       TECO is a character-oriented text editor, originally developed by Dan
  67       Murphy at MIT circa 1962. It is also a Turing-complete imperative
  68       interpreted programming language for text manipulation, done via
  69       user-loaded sets of macros. In fact, the venerable Emacs was born as a set
  70       of Editor MACroS for TECO.
  71
  72       TECOC is a portable C implementation of TECO-11.
  73     '';
  74     license = {
  75       url = "https://github.com/blakemcbride/TECOC/blob/${finalAttrs.src.rev}/doc/readme-1st.txt";
  76     };
  77     maintainers = [ lib.maintainers.AndersonTorres ];
  78     platforms = lib.platforms.unix;
  79   };
  80 })