pkgs/development/compilers/mlton/20210107-binary.nix

   1 { lib, stdenv, fetchurl, patchelf, gmp }:
   2 let
   3   dynamic-linker = stdenv.cc.bintools.dynamicLinker;
   4 in
   5 stdenv.mkDerivation rec {
   6   pname = "mlton";
   7   version = "20210107";
   8
   9   src =
  10     if stdenv.hostPlatform.system == "x86_64-linux" then
  11       (fetchurl {
  12         url = "https://github.com/MLton/mlton/releases/download/on-${version}-release/${pname}-${version}-1.amd64-linux-glibc2.31.tgz.tgz";
  13         sha256 = "0f4q575yfm5dpg4a2wsnqn4l2zrar96p6rlsk0dw10ggyfwvsjlf";
  14       })
  15     else if stdenv.hostPlatform.system == "x86_64-darwin" then
  16       (fetchurl {
  17         url = "https://github.com/MLton/mlton/releases/download/on-${version}-release/${pname}-${version}-1.amd64-darwin-19.6.gmp-static.tgz";
  18         sha256 = "1cw7yhw48qp12q0adwf8srpjzrgkp84kmlkqw3pz8vkxz4p9hbdv";
  19       })
  20     else
  21       throw "Architecture not supported";
  22
  23   buildInputs = [ gmp ];
  24   nativeBuildInputs = lib.optional stdenv.isLinux patchelf;
  25
  26   buildPhase = ''
  27     make update \
  28       CC="$(type -p cc)" \
  29       WITH_GMP_INC_DIR="${gmp.dev}/include" \
  30       WITH_GMP_LIB_DIR="${gmp}/lib"
  31   '';
  32
  33   installPhase = ''
  34     make install PREFIX=$out
  35   '';
  36
  37   postFixup = lib.optionalString stdenv.isLinux ''
  38     patchelf --set-interpreter ${dynamic-linker} $out/lib/mlton/mlton-compile
  39     patchelf --set-rpath ${gmp}/lib $out/lib/mlton/mlton-compile
  40
  41     for e in mllex mlnlffigen mlprof mlyacc; do
  42       patchelf --set-interpreter ${dynamic-linker} $out/bin/$e
  43       patchelf --set-rpath ${gmp}/lib $out/bin/$e
  44     done
  45   '' + lib.optionalString stdenv.isDarwin ''
  46     install_name_tool -change \
  47       /opt/local/lib/libgmp.10.dylib \
  48       ${gmp}/lib/libgmp.10.dylib \
  49       $out/lib/mlton/mlton-compile
  50
  51     for e in mllex mlnlffigen mlprof mlyacc; do
  52       install_name_tool -change \
  53         /opt/local/lib/libgmp.10.dylib \
  54         ${gmp}/lib/libgmp.10.dylib \
  55         $out/bin/$e
  56     done
  57   '';
  58
  59   meta = import ./meta.nix;
  60 }