pkgs/development/interpreters/guile/3.0.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , fetchpatch
   5 , boehmgc
   6 , buildPackages
   7 , coverageAnalysis ? null
   8 , gawk
   9 , gmp
  10 , libffi
  11 , libtool
  12 , libunistring
  13 , libxcrypt
  14 , makeWrapper
  15 , pkg-config
  16 , pkgsBuildBuild
  17 , readline
  18 , writeScript
  19 }:
  20
  21 let
  22   # Do either a coverage analysis build or a standard build.
  23   builder = if coverageAnalysis != null
  24             then coverageAnalysis
  25             else stdenv.mkDerivation;
  26 in
  27 builder rec {
  28   pname = "guile";
  29   version = "3.0.9";
  30
  31   src = fetchurl {
  32     url = "mirror://gnu/${pname}/${pname}-${version}.tar.xz";
  33     sha256 = "sha256-GiYlrHKyNm6VeS8/51j9Lfd1tARKkKSpeHMm5mwNdQ0=";
  34   };
  35
  36   outputs = [ "out" "dev" "info" ];
  37   setOutputFlags = false; # $dev gets into the library otherwise
  38
  39   depsBuildBuild = [
  40     buildPackages.stdenv.cc
  41   ] ++ lib.optional (stdenv.hostPlatform != stdenv.buildPlatform)
  42     pkgsBuildBuild.guile_3_0;
  43   nativeBuildInputs = [
  44     makeWrapper
  45     pkg-config
  46   ];
  47   buildInputs = [
  48     libffi
  49     libtool
  50     libunistring
  51     readline
  52   ] ++ lib.optionals stdenv.isLinux [
  53     libxcrypt
  54   ];
  55   propagatedBuildInputs = [
  56     boehmgc
  57     gmp
  58
  59     # These ones aren't normally needed here, but `libguile*.la' has '-l'
  60     # flags for them without corresponding '-L' flags. Adding them here will
  61     # add the needed `-L' flags.  As for why the `.la' file lacks the `-L'
  62     # flags, see below.
  63     libtool
  64     libunistring
  65   ] ++ lib.optionals stdenv.isLinux [
  66     libxcrypt
  67   ];
  68
  69   # According to
  70   # https://git.savannah.gnu.org/cgit/guix.git/tree/gnu/packages/guile.scm?h=a39207f7afd977e4e4299c6f0bb34bcb6d153818#n405
  71   # starting with Guile 3.0.8, parallel builds can be done
  72   # bit-reproducibly as long as we're not cross-compiling
  73   enableParallelBuilding = stdenv.buildPlatform == stdenv.hostPlatform;
  74
  75   patches = [
  76     ./eai_system.patch
  77   ] ++ lib.optional (coverageAnalysis != null) ./gcov-file-name.patch
  78   ++ lib.optional stdenv.isDarwin
  79     (fetchpatch {
  80       url = "https://gitlab.gnome.org/GNOME/gtk-osx/raw/52898977f165777ad9ef169f7d4818f2d4c9b731/patches/guile-clocktime.patch";
  81       sha256 = "12wvwdna9j8795x59ldryv9d84c1j3qdk2iskw09306idfsis207";
  82     });
  83
  84   # Explicitly link against libgcc_s, to work around the infamous
  85   # "libgcc_s.so.1 must be installed for pthread_cancel to work".
  86
  87   # don't have "libgcc_s.so.1" on clang
  88   LDFLAGS = lib.optionalString
  89     (stdenv.cc.isGNU && !stdenv.hostPlatform.isStatic) "-lgcc_s";
  90
  91   configureFlags = [
  92     "--with-libreadline-prefix=${lib.getDev readline}"
  93   ] ++ lib.optionals stdenv.isSunOS [
  94     # Make sure the right <gmp.h> is found, and not the incompatible
  95     # /usr/include/mp.h from OpenSolaris.  See
  96     # <https://lists.gnu.org/archive/html/hydra-users/2012-08/msg00000.html>
  97     # for details.
  98     "--with-libgmp-prefix=${lib.getDev gmp}"
  99
 100     # Same for these (?).
 101     "--with-libunistring-prefix=${libunistring}"
 102
 103     # See below.
 104     "--without-threads"
 105   ]
 106   # At least on x86_64-darwin '-flto' autodetection is not correct:
 107   #  https://github.com/NixOS/nixpkgs/pull/160051#issuecomment-1046193028
 108   ++ lib.optional (stdenv.isDarwin) "--disable-lto";
 109
 110   postInstall = ''
 111     wrapProgram $out/bin/guile-snarf --prefix PATH : "${gawk}/bin"
 112   ''
 113   # XXX: See http://thread.gmane.org/gmane.comp.lib.gnulib.bugs/18903 for
 114   # why `--with-libunistring-prefix' and similar options coming from
 115   # `AC_LIB_LINKFLAGS_BODY' don't work on NixOS/x86_64.
 116   + ''
 117     sed -i "$out/lib/pkgconfig/guile"-*.pc    \
 118         -e "s|-lunistring|-L${libunistring}/lib -lunistring|g ;
 119             s|-lltdl|-L${libtool.lib}/lib -lltdl|g ;
 120             s|-lcrypt|-L${libxcrypt}/lib -lcrypt|g ;
 121             s|^Cflags:\(.*\)$|Cflags: -I${libunistring.dev}/include \1|g ;
 122             s|includedir=$out|includedir=$dev|g
 123             "
 124     '';
 125
 126   # make check doesn't work on darwin
 127   # On Linuxes+Hydra the tests are flaky; feel free to investigate deeper.
 128   doCheck = false;
 129   doInstallCheck = doCheck;
 130
 131   # In procedure bytevector-u8-ref: Argument 2 out of range
 132   dontStrip = stdenv.isDarwin;
 133
 134   setupHook = ./setup-hook-3.0.sh;
 135
 136   passthru = rec {
 137     effectiveVersion = lib.versions.majorMinor version;
 138     siteCcacheDir = "lib/guile/${effectiveVersion}/site-ccache";
 139     siteDir = "share/guile/site/${effectiveVersion}";
 140
 141     updateScript = writeScript "update-guile-3" ''
 142       #!/usr/bin/env nix-shell
 143       #!nix-shell -i bash -p curl pcre common-updater-scripts
 144
 145       set -eu -o pipefail
 146
 147       # Expect the text in format of '"https://ftp.gnu.org/gnu/guile/guile-3.0.8.tar.gz"'
 148       new_version="$(curl -s https://www.gnu.org/software/guile/download/ |
 149           pcregrep -o1 '"https://ftp.gnu.org/gnu/guile/guile-(3[.0-9]+).tar.gz"')"
 150       update-source-version guile_3_0 "$new_version"
 151     '';
 152   };
 153
 154   meta = with lib; {
 155     homepage = "https://www.gnu.org/software/guile/";
 156     description = "Embeddable Scheme implementation";
 157     longDescription = ''
 158       GNU Guile is an implementation of the Scheme programming language, with
 159       support for many SRFIs, packaged for use in a wide variety of
 160       environments.  In addition to implementing the R5RS Scheme standard and a
 161       large subset of R6RS, Guile includes a module system, full access to POSIX
 162       system calls, networking support, multiple threads, dynamic linking, a
 163       foreign function call interface, and powerful string processing.
 164     '';
 165     license = licenses.lgpl3Plus;
 166     maintainers = with maintainers; [ ludo lovek323 vrthra ];
 167     platforms = platforms.all;
 168   };
 169 }