pkgs/development/interpreters/tcl/mk-tcl-derivation.nix

   1 # Generic builder for tcl packages/applications, generally based on mk-python-derivation.nix
   2 { tcl
   3 , lib
   4 , makeWrapper
   5 , runCommand
   6 , writeScript
   7 }:
   8
   9 { buildInputs ? []
  10 , nativeBuildInputs ? []
  11 , propagatedBuildInputs ? []
  12 , checkInputs ? []
  13 , nativeCheckInputs ? []
  14
  15 # true if we should skip the configuration phase altogether
  16 , dontConfigure ? false
  17
  18 # Extra flags passed to configure step
  19 , configureFlags ? []
  20
  21 # Whether or not we should add common Tcl-related configure flags
  22 , addTclConfigureFlags ? true
  23
  24 , meta ? {}
  25 , passthru ? {}
  26 , doCheck ? true
  27 , ... } @ attrs:
  28
  29 let
  30   inherit (tcl) stdenv;
  31   inherit (lib) getBin optionalAttrs;
  32
  33   defaultTclPkgConfigureFlags = [
  34     "--with-tcl=${tcl}/lib"
  35     "--with-tclinclude=${tcl}/include"
  36     "--exec-prefix=${placeholder "out"}"
  37   ];
  38
  39   self = (stdenv.mkDerivation ((builtins.removeAttrs attrs [
  40     "addTclConfigureFlags" "checkPhase" "checkInputs" "nativeCheckInputs" "doCheck"
  41   ]) // {
  42
  43     buildInputs = buildInputs ++ [ tcl.tclPackageHook ];
  44     nativeBuildInputs = nativeBuildInputs ++ [ makeWrapper tcl ];
  45     propagatedBuildInputs = propagatedBuildInputs ++ [ tcl ];
  46
  47     TCLSH = "${getBin tcl}/bin/tclsh";
  48
  49     # Run tests after install, at which point we've done all TCLLIBPATH setup
  50     doCheck = false;
  51     doInstallCheck = attrs.doCheck or (attrs.doInstallCheck or false);
  52     installCheckInputs = checkInputs ++ (attrs.installCheckInputs or []);
  53     nativeInstallCheckInputs = nativeCheckInputs ++ (attrs.nativeInstallCheckInputs or []);
  54
  55     # Add typical values expected by TEA for configureFlags
  56     configureFlags =
  57       if (!dontConfigure && addTclConfigureFlags)
  58         then (configureFlags ++ defaultTclPkgConfigureFlags)
  59         else configureFlags;
  60
  61     meta = {
  62       platforms = tcl.meta.platforms;
  63     } // meta;
  64
  65
  66   } // optionalAttrs (attrs?checkPhase) {
  67     installCheckPhase = attrs.checkPhase;
  68   }
  69   ));
  70
  71 in lib.extendDerivation true passthru self