pkgs/development/libraries/gamin/default.nix

   1 { lib, stdenv, fetchurl, fetchpatch, pkg-config, glib, autoreconfHook }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "gamin";
   5   version = "0.1.10";
   6
   7   src = fetchurl {
   8     url = "https://www.gnome.org/~veillard/gamin/sources/gamin-${version}.tar.gz";
   9     sha256 = "18cr51y5qacvs2fc2p1bqv32rs8bzgs6l67zhasyl45yx055y218";
  10   };
  11
  12   nativeBuildInputs = [ pkg-config autoreconfHook ];
  13
  14   buildInputs = [ glib ];
  15
  16   # `_GNU_SOURCE' is needed, e.g., to get `struct ucred' from
  17   # <sys/socket.h> with Glibc 2.9.
  18   configureFlags = [
  19     "--disable-debug"
  20     "--without-python" # python3 not supported
  21     "CPPFLAGS=-D_GNU_SOURCE"
  22   ];
  23
  24   preBuild = lib.optionalString stdenv.isDarwin ''
  25     sed -i 's/,--version-script=.*$/\\/' libgamin/Makefile
  26   '';
  27
  28   patches = [ ./deadlock.patch ]
  29     ++ map fetchurl (import ./debian-patches.nix)
  30     ++ lib.optional stdenv.cc.isClang ./returnval.patch
  31     ++ lib.optional stdenv.hostPlatform.isMusl (fetchpatch {
  32       name = "fix-pthread-mutex.patch";
  33       url = "https://git.alpinelinux.org/aports/plain/main/gamin/fix-pthread-mutex.patch?h=3.4-stable&id=a1a836b089573752c1b0da7d144c0948b04e8ea8";
  34       sha256 = "13igdbqsxb3sz0h417k6ifmq2n4siwqspj6slhc7fdl5wd1fxmdz";
  35     }) ++ lib.optional (stdenv.hostPlatform != stdenv.buildPlatform) ./abstract-socket-namespace.patch;
  36
  37
  38   meta = with lib; {
  39     homepage    = "https://people.gnome.org/~veillard/gamin/";
  40     description = "A file and directory monitoring system";
  41     maintainers = with maintainers; [ lovek323 ];
  42     license = licenses.gpl2;
  43     platforms   = platforms.unix;
  44   };
  45 }
  46