pkgs/development/libraries/libpeas/default.nix

   1 { stdenv
   2 , lib
   3 , fetchurl
   4 , meson
   5 , ninja
   6 , pkg-config
   7 , gettext
   8 , gi-docgen
   9 , gnome
  10 , glib
  11 , gtk3
  12 , gobject-introspection
  13 , python3
  14 , ncurses
  15 }:
  16
  17 stdenv.mkDerivation rec {
  18   pname = "libpeas";
  19   version = "1.36.0";
  20
  21   outputs = [ "out" "dev" "devdoc" ];
  22
  23   src = fetchurl {
  24     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  25     sha256 = "KXy5wszNjoYXYj0aPoQVtFMLjlqJPjUnu/0e3RMje0w=";
  26   };
  27
  28   depsBuildBuild = [
  29     pkg-config
  30   ];
  31
  32   nativeBuildInputs = [
  33     pkg-config
  34     meson
  35     ninja
  36     gettext
  37     gi-docgen
  38     gobject-introspection
  39   ];
  40
  41   buildInputs = [
  42     glib
  43     gtk3
  44     ncurses
  45     python3
  46     python3.pkgs.pygobject3
  47   ];
  48
  49   propagatedBuildInputs = [
  50     # Required by libpeas-1.0.pc
  51     gobject-introspection
  52   ];
  53
  54   mesonFlags = [
  55     "-Dgtk_doc=true"
  56   ];
  57
  58   postFixup = ''
  59     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
  60     moveToOutput "share/doc" "$devdoc"
  61   '';
  62
  63   passthru = {
  64     updateScript = gnome.updateScript {
  65       packageName = pname;
  66       versionPolicy = "odd-unstable";
  67       freeze = true;
  68     };
  69   };
  70
  71   meta = with lib; {
  72     description = "A GObject-based plugins engine";
  73     homepage = "https://wiki.gnome.org/Projects/Libpeas";
  74     license = licenses.gpl2Plus;
  75     platforms = platforms.unix;
  76     maintainers = teams.gnome.members;
  77   };
  78 }