pkgs/development/libraries/libportal/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , fetchpatch
   5 , meson
   6 , ninja
   7 , pkg-config
   8 , gobject-introspection
   9 , vala
  10 , gi-docgen
  11 , glib
  12 , gtk3
  13 , gtk4
  14 , libsForQt5
  15 , variant ? null
  16 }:
  17
  18 assert variant == null || variant == "gtk3" || variant == "gtk4" || variant == "qt5";
  19
  20 stdenv.mkDerivation rec {
  21   pname = "libportal" + lib.optionalString (variant != null) "-${variant}";
  22   version = "0.6";
  23
  24   outputs = [ "out" "dev" ]
  25     ++ lib.optional (variant != "qt5") "devdoc";
  26
  27   src = fetchFromGitHub {
  28     owner = "flatpak";
  29     repo = "libportal";
  30     rev = version;
  31     sha256 = "sha256-wDDE43UC6FBgPYLS+WWExeheURCH/3fCKu5oJg7GM+A=";
  32   };
  33
  34   # TODO: remove on 0.7
  35   patches = [
  36     # https://github.com/flatpak/libportal/pull/107
  37     (fetchpatch {
  38       name = "check-presence-of-sys-vfs-h.patch";
  39       url = "https://github.com/flatpak/libportal/commit/e91a5d2ceb494ca0dd67295736e671b0142c7540.patch";
  40       sha256 = "sha256-uFyhlU2fJgW4z0I31fABdc+pimLFYkqM4lggSIFs1tw=";
  41     })
  42   ];
  43
  44   depsBuildBuild = [
  45     pkg-config
  46   ];
  47
  48   nativeBuildInputs = [
  49     meson
  50     ninja
  51     pkg-config
  52     gi-docgen
  53   ] ++ lib.optionals (variant != "qt5") [
  54     gobject-introspection
  55     vala
  56   ];
  57
  58   propagatedBuildInputs = [
  59     glib
  60   ] ++ lib.optionals (variant == "gtk3") [
  61     gtk3
  62   ] ++ lib.optionals (variant == "gtk4") [
  63     gtk4
  64   ] ++ lib.optionals (variant == "qt5") [
  65     libsForQt5.qtbase
  66     libsForQt5.qtx11extras
  67   ];
  68
  69   mesonFlags = [
  70     "-Dbackends=${lib.optionalString (variant != null) variant}"
  71     "-Dvapi=${if variant != "qt5" then "true" else "false"}"
  72     "-Dintrospection=${if variant != "qt5" then "true" else "false"}"
  73     "-Ddocs=${if variant != "qt5" then "true" else "false"}" # requires introspection=true
  74   ];
  75
  76   postFixup = ''
  77     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
  78     moveToOutput "share/doc" "$devdoc"
  79   '';
  80
  81   # we don't have any binaries
  82   dontWrapQtApps = true;
  83
  84   meta = with lib; {
  85     description = "Flatpak portal library";
  86     homepage = "https://github.com/flatpak/libportal";
  87     license = licenses.lgpl3Plus;
  88     maintainers = with maintainers; [ jtojnar ];
  89     platforms = platforms.unix;
  90   };
  91 }