pkgs/development/libraries/mesa-glu/default.nix

   1 { lib, stdenv, fetchurl
   2 , meson, ninja
   3 , pkg-config, libGL, ApplicationServices
   4 , testers
   5 , gitUpdater
   6 }:
   7
   8 stdenv.mkDerivation (finalAttrs: {
   9   pname = "glu";
  10   version = "9.0.3";
  11
  12   src = let
  13     inherit (finalAttrs) pname version;
  14   in fetchurl {
  15     url = "https://mesa.freedesktop.org/archive/${pname}/${pname}-${version}.tar.xz";
  16     hash = "sha256-vUP+EvN0sRkusV/iDkX/RWubwmq1fw7ukZ+Wyg+KMw8=";
  17   };
  18
  19   nativeBuildInputs = [ meson ninja pkg-config ];
  20   propagatedBuildInputs = [ libGL ]
  21     ++ lib.optional stdenv.isDarwin ApplicationServices;
  22
  23   outputs = [ "out" "dev" ];
  24
  25   enableParallelBuilding = true;
  26
  27   passthru = {
  28     tests = {
  29       pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
  30     };
  31     updateScript = gitUpdater {
  32       # No nicer place to find latest release.
  33       url = "https://gitlab.freedesktop.org/mesa/glu";
  34     rev-prefix = "glu-";
  35     };
  36   };
  37
  38   meta = {
  39     description = "OpenGL utility library";
  40     homepage = "https://cgit.freedesktop.org/mesa/glu/";
  41     license = lib.licenses.sgi-b-20;
  42     pkgConfigModules = [ "glu" ];
  43     platforms = lib.platforms.unix;
  44     broken = stdenv.hostPlatform.isAndroid;
  45   };
  46 })