pkgs/development/libraries/portaudio/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , alsa-lib
   5 , libjack2
   6 , pkg-config
   7 , which
   8 , AudioUnit
   9 , AudioToolbox
  10 , CoreAudio
  11 , CoreServices
  12 , Carbon }:
  13
  14 stdenv.mkDerivation rec {
  15   pname = "portaudio";
  16   version = "190700_20210406";
  17
  18   src = fetchurl {
  19     url = "https://files.portaudio.com/archives/pa_stable_v${version}.tgz";
  20     sha256 = "1vrdrd42jsnffh6rq8ap2c6fr4g9fcld89z649fs06bwqx1bzvs7";
  21   };
  22
  23   strictDeps = true;
  24   nativeBuildInputs = [ pkg-config which ];
  25   buildInputs = [ libjack2 ] ++ lib.optionals (!stdenv.isDarwin) [ alsa-lib ];
  26
  27   configureFlags = [ "--disable-mac-universal" "--enable-cxx" ];
  28
  29   env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-error=nullability-inferred-on-nested-type -Wno-error=nullability-completeness-on-arrays -Wno-error=implicit-const-int-float-conversion";
  30
  31   propagatedBuildInputs = lib.optionals stdenv.isDarwin [ AudioUnit AudioToolbox CoreAudio CoreServices Carbon ];
  32
  33   # Disable parallel build as it fails as:
  34   #   make: *** No rule to make target '../../../lib/libportaudio.la',
  35   #     needed by 'libportaudiocpp.la'.  Stop.
  36   # Next release should address it with
  37   #     https://github.com/PortAudio/portaudio/commit/28d2781d9216115543aa3f0a0ffb7b4ee0fac551.patch
  38   enableParallelBuilding = false;
  39
  40   postPatch = ''
  41     # workaround for the configure script which expects an absolute path
  42     export AR=$(which $AR)
  43   '';
  44
  45   # not sure why, but all the headers seem to be installed by the make install
  46   installPhase = ''
  47     make install
  48   '' + lib.optionalString (!stdenv.isDarwin) ''
  49     # fixup .pc file to find alsa library
  50     sed -i "s|-lasound|-L${alsa-lib.out}/lib -lasound|" "$out/lib/pkgconfig/"*.pc
  51   '' + lib.optionalString stdenv.isDarwin ''
  52     cp include/pa_mac_core.h $out/include/pa_mac_core.h
  53   '';
  54
  55   meta = with lib; {
  56     description = "Portable cross-platform Audio API";
  57     homepage    = "https://www.portaudio.com/";
  58     # Not exactly a bsd license, but alike
  59     license     = licenses.mit;
  60     maintainers = with maintainers; [ lovek323 ];
  61     platforms   = platforms.unix;
  62   };
  63
  64   passthru = {
  65     api_version = 19;
  66   };
  67 }