pkgs/development/libraries/readline/6.3.nix

   1 { fetchurl, lib, stdenv, ncurses }:
   2
   3 stdenv.mkDerivation {
   4   pname = "readline";
   5   version = "6.3p08";
   6
   7   src = fetchurl {
   8     url = "mirror://gnu/readline/readline-6.3.tar.gz";
   9     sha256 = "0hzxr9jxqqx5sxsv9vmlxdnvlr9vi4ih1avjb869hbs6p5qn1fjn";
  10   };
  11
  12   outputs = [ "out" "dev" "man" "doc" "info" ];
  13
  14   strictDeps = true;
  15   propagatedBuildInputs = [ ncurses ];
  16
  17   patchFlags = [ "-p0" ];
  18
  19   configureFlags = lib.optional (stdenv.hostPlatform != stdenv.buildPlatform)
  20     # This test requires running host code
  21     "bash_cv_wcwidth_broken=no";
  22
  23   patches =
  24     [ ./link-against-ncurses.patch
  25       ./no-arch_only-6.3.patch
  26     ] ++ lib.optional stdenv.hostPlatform.useAndroidPrebuilt ./android.patch
  27     ++
  28     (let
  29        patch = nr: sha256:
  30          fetchurl {
  31            url = "mirror://gnu/readline/readline-6.3-patches/readline63-${nr}";
  32            inherit sha256;
  33          };
  34      in
  35        import ./readline-6.3-patches.nix patch);
  36
  37   meta = with lib; {
  38     description = "Library for interactive line editing";
  39
  40     longDescription = ''
  41       The GNU Readline library provides a set of functions for use by
  42       applications that allow users to edit command lines as they are
  43       typed in.  Both Emacs and vi editing modes are available.  The
  44       Readline library includes additional functions to maintain a
  45       list of previously-entered command lines, to recall and perhaps
  46       reedit those lines, and perform csh-like history expansion on
  47       previous commands.
  48
  49       The history facilities are also placed into a separate library,
  50       the History library, as part of the build process.  The History
  51       library may be used without Readline in applications which
  52       desire its capabilities.
  53     '';
  54
  55     homepage = "https://savannah.gnu.org/projects/readline/";
  56
  57     license = licenses.gpl3Plus;
  58
  59     maintainers = [ ];
  60
  61     platforms = platforms.unix;
  62     branch = "6.3";
  63   };
  64 }