pkgs/development/libraries/webkitgtk/default.nix

   1 { lib
   2 , stdenv
   3 , runCommand
   4 , fetchurl
   5 , perl
   6 , python3
   7 , ruby
   8 , gi-docgen
   9 , bison
  10 , gperf
  11 , cmake
  12 , ninja
  13 , pkg-config
  14 , gettext
  15 , gobject-introspection
  16 , gnutls
  17 , libgcrypt
  18 , libgpg-error
  19 , gtk3
  20 , wayland
  21 , wayland-protocols
  22 , libwebp
  23 , libwpe
  24 , libwpe-fdo
  25 , enchant2
  26 , xorg
  27 , libxkbcommon
  28 , libavif
  29 , libepoxy
  30 , libjxl
  31 , at-spi2-core
  32 , libxml2
  33 , libsoup
  34 , libsecret
  35 , libxslt
  36 , harfbuzz
  37 , libpthreadstubs
  38 , nettle
  39 , libtasn1
  40 , p11-kit
  41 , libidn
  42 , libedit
  43 , readline
  44 , apple_sdk
  45 , libGL
  46 , libGLU
  47 , mesa
  48 , libintl
  49 , lcms2
  50 , libmanette
  51 , openjpeg
  52 , geoclue2
  53 , sqlite
  54 , gst-plugins-base
  55 , gst-plugins-bad
  56 , woff2
  57 , bubblewrap
  58 , libseccomp
  59 , systemd
  60 , xdg-dbus-proxy
  61 , substituteAll
  62 , glib
  63 , unifdef
  64 , addOpenGLRunpath
  65 , enableGeoLocation ? true
  66 , withLibsecret ? true
  67 , systemdSupport ? lib.meta.availableOn stdenv.hostPlatform systemd
  68 , testers
  69 }:
  70
  71 stdenv.mkDerivation (finalAttrs: {
  72   pname = "webkitgtk";
  73   version = "2.42.2";
  74   name = "${finalAttrs.pname}-${finalAttrs.version}+abi=${if lib.versionAtLeast gtk3.version "4.0" then "6.0" else "4.${if lib.versions.major libsoup.version == "2" then "0" else "1"}"}";
  75
  76   outputs = [ "out" "dev" "devdoc" ];
  77
  78   # https://github.com/NixOS/nixpkgs/issues/153528
  79   # Can't be linked within a 4GB address space.
  80   separateDebugInfo = stdenv.isLinux && !stdenv.is32bit;
  81
  82   src = fetchurl {
  83     url = "https://webkitgtk.org/releases/webkitgtk-${finalAttrs.version}.tar.xz";
  84     hash = "sha256-VyCqPoYn8bn2MlIYfU3w+CM65x1pexeW6/vlynUL0Rg=";
  85   };
  86
  87   patches = lib.optionals stdenv.isLinux [
  88     (substituteAll {
  89       src = ./fix-bubblewrap-paths.patch;
  90       inherit (builtins) storeDir;
  91       inherit (addOpenGLRunpath) driverLink;
  92     })
  93
  94     # Hardcode path to WPE backend
  95     # https://github.com/NixOS/nixpkgs/issues/110468
  96     (substituteAll {
  97       src = ./fdo-backend-path.patch;
  98       wpebackend_fdo = libwpe-fdo;
  99     })
 100   ];
 101
 102   preConfigure = lib.optionalString (stdenv.hostPlatform != stdenv.buildPlatform) ''
 103     # Ignore gettext in cmake_prefix_path so that find_program doesn't
 104     # pick up the wrong gettext. TODO: Find a better solution for
 105     # this, maybe make cmake not look up executables in
 106     # CMAKE_PREFIX_PATH.
 107     cmakeFlags+=" -DCMAKE_IGNORE_PATH=${lib.getBin gettext}/bin"
 108   '';
 109
 110   nativeBuildInputs = [
 111     bison
 112     cmake
 113     gettext
 114     gobject-introspection
 115     gperf
 116     ninja
 117     perl
 118     perl.pkgs.FileCopyRecursive # used by copy-user-interface-resources.pl
 119     pkg-config
 120     python3
 121     ruby
 122     gi-docgen
 123     glib # for gdbus-codegen
 124     unifdef
 125   ] ++ lib.optionals stdenv.isLinux [
 126     wayland # for wayland-scanner
 127   ];
 128
 129   buildInputs = [
 130     at-spi2-core
 131     enchant2
 132     libavif
 133     libepoxy
 134     libjxl
 135     gnutls
 136     gst-plugins-bad
 137     gst-plugins-base
 138     harfbuzz
 139     libGL
 140     libGLU
 141     mesa # for libEGL headers
 142     libgcrypt
 143     libgpg-error
 144     libidn
 145     libintl
 146     lcms2
 147     libpthreadstubs
 148     libtasn1
 149     libwebp
 150     libxkbcommon
 151     libxml2
 152     libxslt
 153     nettle
 154     openjpeg
 155     p11-kit
 156     sqlite
 157     woff2
 158   ] ++ (with xorg; [
 159     libXdamage
 160     libXdmcp
 161     libXt
 162     libXtst
 163   ]) ++ lib.optionals stdenv.isDarwin [
 164     libedit
 165     readline
 166   ] ++ lib.optional (stdenv.isDarwin && !stdenv.isAarch64) (
 167     # Pull a header that contains a definition of proc_pid_rusage().
 168     # (We pick just that one because using the other headers from `sdk` is not
 169     # compatible with our C++ standard library. This header is already in
 170     # the standard library on aarch64)
 171     runCommand "webkitgtk_headers" { } ''
 172       install -Dm444 "${lib.getDev apple_sdk.sdk}"/include/libproc.h "$out"/include/libproc.h
 173     ''
 174   ) ++ lib.optionals stdenv.isLinux [
 175     libseccomp
 176     libmanette
 177     wayland
 178     libwpe
 179     libwpe-fdo
 180   ] ++ lib.optionals systemdSupport [
 181     systemd
 182   ] ++ lib.optionals enableGeoLocation [
 183     geoclue2
 184   ] ++ lib.optionals withLibsecret [
 185     libsecret
 186   ] ++ lib.optionals (lib.versionAtLeast gtk3.version "4.0") [
 187     xorg.libXcomposite
 188     wayland-protocols
 189   ];
 190
 191   propagatedBuildInputs = [
 192     gtk3
 193     libsoup
 194   ];
 195
 196   cmakeFlags = let
 197     cmakeBool = x: if x then "ON" else "OFF";
 198   in [
 199     "-DENABLE_INTROSPECTION=ON"
 200     "-DPORT=GTK"
 201     "-DUSE_LIBHYPHEN=OFF"
 202     "-DUSE_SOUP2=${cmakeBool (lib.versions.major libsoup.version == "2")}"
 203     "-DUSE_LIBSECRET=${cmakeBool withLibsecret}"
 204   ] ++ lib.optionals stdenv.isLinux [
 205     # Have to be explicitly specified when cross.
 206     # https://github.com/WebKit/WebKit/commit/a84036c6d1d66d723f217a4c29eee76f2039a353
 207     "-DBWRAP_EXECUTABLE=${lib.getExe bubblewrap}"
 208     "-DDBUS_PROXY_EXECUTABLE=${lib.getExe xdg-dbus-proxy}"
 209   ] ++ lib.optionals stdenv.isDarwin [
 210     "-DENABLE_GAMEPAD=OFF"
 211     "-DENABLE_GTKDOC=OFF"
 212     "-DENABLE_MINIBROWSER=OFF"
 213     "-DENABLE_QUARTZ_TARGET=ON"
 214     "-DENABLE_X11_TARGET=OFF"
 215     "-DUSE_APPLE_ICU=OFF"
 216     "-DUSE_OPENGL_OR_ES=OFF"
 217   ] ++ lib.optionals (lib.versionAtLeast gtk3.version "4.0") [
 218     "-DUSE_GTK4=ON"
 219   ] ++ lib.optionals (!systemdSupport) [
 220     "-DENABLE_JOURNALD_LOG=OFF"
 221   ];
 222
 223   postPatch = ''
 224     patchShebangs .
 225   '';
 226
 227   postFixup = ''
 228     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
 229     moveToOutput "share/doc" "$devdoc"
 230   '';
 231
 232   requiredSystemFeatures = [ "big-parallel" ];
 233
 234   passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
 235
 236   meta = with lib; {
 237     description = "Web content rendering engine, GTK port";
 238     homepage = "https://webkitgtk.org/";
 239     license = licenses.bsd2;
 240     pkgConfigModules = [
 241       "javascriptcoregtk-4.0"
 242       "webkit2gtk-4.0"
 243       "webkit2gtk-web-extension-4.0"
 244     ];
 245     platforms = platforms.linux ++ platforms.darwin;
 246     maintainers = teams.gnome.members;
 247     broken = stdenv.isDarwin;
 248   };
 249 })