pkgs/development/libraries/zookeeper_mt/default.nix

   1 { lib, stdenv
   2 , fetchurl
   3 , autoreconfHook
   4 , jre
   5 , openssl
   6 , pkg-config
   7 # We depend on ZooKeeper for the Jute compiler.
   8 , zookeeper
   9 }:
  10
  11 stdenv.mkDerivation rec {
  12   pname = "zookeeper_mt";
  13   version = lib.getVersion zookeeper;
  14
  15   src = fetchurl {
  16     url = "mirror://apache/zookeeper/${zookeeper.pname}-${version}/apache-${zookeeper.pname}-${version}.tar.gz";
  17     hash = "sha512-V1SFPtSytFZMyiR/cgwLA9zPUK5xuarP3leQCQiSfelUHnYMB+R6ZQfSHMHD9t+URvLc+KRFSriLTzethspkpA==";
  18   };
  19
  20   sourceRoot = "apache-${zookeeper.pname}-${version}/zookeeper-client/zookeeper-client-c";
  21
  22   nativeBuildInputs = [
  23     autoreconfHook
  24     pkg-config
  25     jre
  26   ];
  27
  28   buildInputs = [
  29     openssl
  30     zookeeper
  31   ];
  32
  33   # Generate the C marshallers/unmarshallers for the Jute-encoded
  34   # definitions.
  35   preConfigure = ''
  36     mkdir generated
  37     cd generated
  38     java -cp ${zookeeper}/lib/${zookeeper.pname}-jute-${version}.jar \
  39         org.apache.jute.compiler.generated.Rcc -l c \
  40         ../../../zookeeper-jute/src/main/resources/zookeeper.jute
  41     cd ..
  42   '';
  43
  44   configureFlags = [
  45     # We're not going to start test servers in the sandbox anyway.
  46     "--without-cppunit"
  47   ];
  48
  49   meta = with lib; {
  50     homepage = "https://zookeeper.apache.org";
  51     description = "Apache Zookeeper";
  52     license = licenses.asl20;
  53     maintainers = with maintainers; [ commandodev ztzg ];
  54     platforms = platforms.unix;
  55   };
  56 }