pkgs/development/tools/apksigner/default.nix

   1 { lib
   2 , stdenv
   3 , fetchgit
   4 , openjdk17_headless
   5 , gradle_7
   6 , perl
   7 , makeWrapper
   8 }:
   9 let
  10   gradle = gradle_7;
  11 in
  12 stdenv.mkDerivation rec {
  13   pname = "apksigner";
  14   version = "33.0.1";
  15
  16   src = fetchgit {
  17     # use pname here because the final jar uses this as the filename
  18     name = pname;
  19     url = "https://android.googlesource.com/platform/tools/apksig";
  20     rev = "platform-tools-${version}";
  21     hash = "sha256-CKvwB9Bb12QvkL/HBOwT6DhA1PI45+QnTNfwnvReGUQ=";
  22   };
  23
  24   postPatch = ''
  25     cat >> build.gradle <<EOF
  26
  27     apply plugin: 'application'
  28     mainClassName = "com.android.apksigner.ApkSignerTool"
  29     sourceSets.main.java.srcDirs = [ 'src/apksigner/java', 'src/main/java' ]
  30     jar {
  31         manifest { attributes "Main-Class": "com.android.apksigner.ApkSignerTool" }
  32         from { (configurations.runtimeClasspath).collect { it.isDirectory() ? it : zipTree(it) } } {
  33             exclude 'META-INF/*.RSA', 'META-INF/*.SF', 'META-INF/*.DSA', 'META-INF/native/*.dll'
  34         }
  35         from('src/apksigner/java') {
  36             include 'com/android/apksigner/*.txt'
  37         }
  38     }
  39     EOF
  40     sed -i -e '/conscrypt/s/testImplementation/implementation/' build.gradle
  41   '';
  42
  43   # fake build to pre-download deps into fixed-output derivation
  44   deps = stdenv.mkDerivation {
  45     pname = "${pname}-deps";
  46     inherit src version postPatch;
  47     nativeBuildInputs = [ gradle perl ];
  48     buildPhase = ''
  49       export GRADLE_USER_HOME=$(mktemp -d)
  50       gradle --no-daemon build
  51     '';
  52     # perl code mavenizes pathes (com.squareup.okio/okio/1.13.0/a9283170b7305c8d92d25aff02a6ab7e45d06cbe/okio-1.13.0.jar -> com/squareup/okio/okio/1.13.0/okio-1.13.0.jar)
  53     installPhase = ''
  54       find $GRADLE_USER_HOME/caches/modules-2 -type f -regex '.*\.\(jar\|pom\)' \
  55         | perl -pe 's#(.*/([^/]+)/([^/]+)/([^/]+)/[0-9a-f]{30,40}/([^/\s]+))$# ($x = $2) =~ tr|\.|/|; "install -Dm444 $1 \$out/$x/$3/$4/''${\($5 =~ s/okio-jvm/okio/r)}" #e' \
  56         | sh
  57     '';
  58     # Don't move info to share/
  59     forceShare = [ "dummy" ];
  60     outputHashMode = "recursive";
  61     # Downloaded jars differ by platform
  62     outputHash = "sha256-cs95YI0SpvzCo5x5trMXlVUGepNKIH9oZ95AfLErKIU=";
  63   };
  64
  65   preBuild = ''
  66     # Use the local packages from -deps
  67     sed -i -e '/repositories {/a maven { url uri("${deps}") }' build.gradle
  68   '';
  69
  70   buildPhase = ''
  71     runHook preBuild
  72
  73     export GRADLE_USER_HOME=$(mktemp -d)
  74     gradle --offline --no-daemon build
  75
  76     runHook postBuild
  77   '';
  78
  79   nativeBuildInputs = [ gradle makeWrapper ];
  80
  81   installPhase = ''
  82     install -Dm444 build/libs/apksigner.jar -t $out/lib
  83     makeWrapper "${openjdk17_headless}/bin/java" "$out/bin/apksigner" \
  84       --add-flags "-jar $out/lib/apksigner.jar"
  85   '';
  86
  87   meta = with lib; {
  88     description = "Command line tool to sign and verify Android APKs";
  89     homepage = "https://developer.android.com/studio/command-line/apksigner";
  90     license = licenses.asl20;
  91     maintainers = with maintainers; [ linsui ];
  92     platforms = platforms.unix;
  93   };
  94 }