pkgs/development/tools/ronn/default.nix

   1 { stdenv, lib, bundlerEnv, bundlerUpdateScript, makeWrapper, groff, callPackage }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "ronn";
   5   version = env.gems.ronn-ng.version;
   6
   7   env = bundlerEnv {
   8     name = "ronn-gems";
   9     gemdir = ./.;
  10   };
  11
  12   dontUnpack = true;
  13
  14   nativeBuildInputs = [
  15     makeWrapper
  16   ];
  17
  18   installPhase = ''
  19     runHook preInstall
  20
  21     mkdir -p $out/bin
  22     makeWrapper ${env}/bin/ronn $out/bin/ronn \
  23       --set PATH ${groff}/bin
  24
  25     runHook postInstall
  26   '';
  27
  28   passthru.updateScript = bundlerUpdateScript "ronn";
  29
  30   passthru.tests.reproducible-html-manpage = callPackage ./test-reproducible-html.nix { };
  31
  32   meta = with lib; {
  33     description = "markdown-based tool for building manpages";
  34     homepage = "https://github.com/apjanke/ronn-ng";
  35     license = licenses.mit;
  36     maintainers = with maintainers; [ zimbatm nicknovitski ];
  37     platforms = env.ruby.meta.platforms;
  38   };
  39 }