pkgs/development/tools/wxformbuilder/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , darwin
   6 , makeWrapper
   7 , shared-mime-info
   8 , boost
   9 , wxGTK32
  10 }:
  11
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "wxformbuilder";
  14   version = "unstable-2023-04-21";
  15
  16   src = fetchFromGitHub {
  17     owner = "wxFormBuilder";
  18     repo = "wxFormBuilder";
  19     rev = "f026a8e1a7f68e794638f637e53845f8f04869ef";
  20     fetchSubmodules = true;
  21     hash = "sha256-48J8osSBb5x9b8MYWZ5QGF6rWgwtcJ0PLLAYViDr50M=";
  22   };
  23
  24   postPatch = ''
  25     substituteInPlace .git-properties \
  26       --replace "\$Format:%h\$" "${builtins.substring 0 7 finalAttrs.src.rev}" \
  27       --replace "\$Format:%(describe)\$" "${builtins.substring 0 7 finalAttrs.src.rev}"
  28     sed -i '/fixup_bundle/d' cmake/macros.cmake
  29   '';
  30
  31   nativeBuildInputs = [
  32     cmake
  33   ] ++ lib.optionals stdenv.isDarwin [
  34     darwin.sigtool
  35     makeWrapper
  36   ] ++ lib.optionals stdenv.isLinux [
  37     shared-mime-info
  38   ];
  39
  40   buildInputs = [
  41     boost
  42     wxGTK32
  43   ] ++ lib.optionals stdenv.isDarwin [
  44     darwin.apple_sdk.frameworks.Cocoa
  45   ];
  46
  47   postInstall = lib.optionalString stdenv.isDarwin ''
  48     mkdir -p $out/{Applications,bin}
  49     mv $out/wxFormBuilder.app $out/Applications
  50     makeWrapper $out/Applications/wxFormBuilder.app/Contents/MacOS/wxFormBuilder $out/bin/wxformbuilder
  51   '';
  52
  53   meta = with lib; {
  54     description = "RAD tool for wxWidgets GUI design";
  55     homepage = "https://github.com/wxFormBuilder/wxFormBuilder";
  56     license = licenses.gpl2Only;
  57     mainProgram = "wxformbuilder";
  58     maintainers = with maintainers; [ matthuszagh wegank ];
  59     platforms = platforms.unix;
  60   };
  61 })