pkgs/development/web/deno/default.nix

   1 { stdenv
   2 , lib
   3 , callPackage
   4 , fetchFromGitHub
   5 , rustPlatform
   6 , cmake
   7 , protobuf
   8 , installShellFiles
   9 , libiconv
  10 , darwin
  11 , librusty_v8 ? callPackage ./librusty_v8.nix { }
  12 }:
  13
  14 rustPlatform.buildRustPackage rec {
  15   pname = "deno";
  16   version = "1.38.2";
  17
  18   src = fetchFromGitHub {
  19     owner = "denoland";
  20     repo = pname;
  21     rev = "v${version}";
  22     hash = "sha256-DLVeI1pnHpUya8muVUP6VNXiLmlaedOOPPef3tHNOng=";
  23   };
  24
  25   cargoHash = "sha256-qTvPpUBinPm3eQ5PLcqdCcZEG5Q6kGyt35mL914K9jk=";
  26
  27   postPatch = ''
  28     # upstream uses lld on aarch64-darwin for faster builds
  29     # within nix lld looks for CoreFoundation rather than CoreFoundation.tbd and fails
  30     substituteInPlace .cargo/config.toml --replace '"-C", "link-arg=-fuse-ld=lld"' ""
  31   '';
  32
  33   # uses zlib-ng but can't dynamically link yet
  34   # https://github.com/rust-lang/libz-sys/issues/158
  35   nativeBuildInputs = [
  36     # required by libz-ng-sys crate
  37     cmake
  38     # required by deno_kv crate
  39     protobuf
  40     installShellFiles
  41   ];
  42   buildInputs = lib.optionals stdenv.isDarwin (
  43     [ libiconv darwin.libobjc ] ++
  44     (with darwin.apple_sdk.frameworks; [ Security CoreServices Metal Foundation QuartzCore ])
  45   );
  46
  47   # work around "error: unknown warning group '-Wunused-but-set-parameter'"
  48   env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-unknown-warning-option";
  49
  50   buildAndTestSubdir = "cli";
  51
  52   # The v8 package will try to download a `librusty_v8.a` release at build time to our read-only filesystem
  53   # To avoid this we pre-download the file and export it via RUSTY_V8_ARCHIVE
  54   RUSTY_V8_ARCHIVE = librusty_v8;
  55
  56   # Tests have some inconsistencies between runs with output integration tests
  57   # Skipping until resolved
  58   doCheck = false;
  59
  60   preInstall = ''
  61     find ./target -name libswc_common${stdenv.hostPlatform.extensions.sharedLibrary} -delete
  62   '';
  63
  64   postInstall = ''
  65     installShellCompletion --cmd deno \
  66       --bash <($out/bin/deno completions bash) \
  67       --fish <($out/bin/deno completions fish) \
  68       --zsh <($out/bin/deno completions zsh)
  69   '';
  70
  71   doInstallCheck = true;
  72   installCheckPhase = ''
  73     runHook preInstallCheck
  74     $out/bin/deno --help
  75     $out/bin/deno --version | grep "deno ${version}"
  76     runHook postInstallCheck
  77   '';
  78
  79   passthru.updateScript = ./update/update.ts;
  80   passthru.tests = callPackage ./tests { };
  81
  82   meta = with lib; {
  83     homepage = "https://deno.land/";
  84     changelog = "https://github.com/denoland/deno/releases/tag/v${version}";
  85     description = "A secure runtime for JavaScript and TypeScript";
  86     longDescription = ''
  87       Deno aims to be a productive and secure scripting environment for the modern programmer.
  88       Deno will always be distributed as a single executable.
  89       Given a URL to a Deno program, it is runnable with nothing more than the ~15 megabyte zipped executable.
  90       Deno explicitly takes on the role of both runtime and package manager.
  91       It uses a standard browser-compatible protocol for loading modules: URLs.
  92       Among other things, Deno is a great replacement for utility scripts that may have been historically written with
  93       bash or python.
  94     '';
  95     license = licenses.mit;
  96     mainProgram = "deno";
  97     maintainers = with maintainers; [ jk ];
  98     platforms = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
  99   };
 100 }