pkgs/games/corsix-th/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , cmake
   5 , doxygen
   6 , ffmpeg
   7 , freetype
   8 , lua
   9 , makeWrapper
  10 , SDL2
  11 , SDL2_mixer
  12 , timidity
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "corsix-th";
  17   version = "0.67";
  18
  19   src = fetchFromGitHub {
  20     owner = "CorsixTH";
  21     repo = "CorsixTH";
  22     rev = "v${finalAttrs.version}";
  23     hash = "sha256-WA/VJqHXzBfVUBNtxCVsGBRzSRQ0pvDvAy03ntc0KZE=";
  24   };
  25
  26   luaEnv = lua.withPackages(p: with p; [ luafilesystem lpeg luasec luasocket ]);
  27   nativeBuildInputs = [ cmake doxygen makeWrapper ];
  28   buildInputs = [ ffmpeg freetype lua finalAttrs.luaEnv SDL2 SDL2_mixer timidity ];
  29   cmakeFlags = [ "-Wno-dev" ];
  30
  31   postInstall = ''
  32     wrapProgram $out/bin/corsix-th \
  33     --set LUA_PATH "$LUA_PATH" \
  34     --set LUA_CPATH "$LUA_CPATH"
  35   '';
  36
  37   meta = with lib; {
  38     description = "A reimplementation of the 1997 Bullfrog business sim Theme Hospital.";
  39     homepage = "https://corsixth.com/";
  40     license = licenses.mit;
  41     maintainers = with maintainers; [ hughobrien ];
  42     platforms = platforms.linux;
  43   };
  44 })