pkgs/games/dwarf-fortress/wrapper/default.nix

   1 { stdenv
   2 , lib
   3 , buildEnv
   4 , substituteAll
   5 , runCommand
   6 , coreutils
   7 , gawk
   8 , dwarf-fortress
   9 , dwarf-therapist
  10 , enableDFHack ? false
  11 , dfhack
  12 , enableSoundSense ? false
  13 , soundSense
  14 , jdk
  15 , enableStoneSense ? false
  16 , enableTWBT ? false
  17 , twbt
  18 , themes ? { }
  19 , theme ? null
  20 , extraPackages ? [ ]
  21   # General config options:
  22 , enableIntro ? true
  23 , enableTruetype ? null # defaults to 24, see init.txt
  24 , enableFPS ? false
  25 , enableTextMode ? false
  26 , enableSound ? true
  27 # An attribute set of settings to override in data/init/*.txt.
  28 # For example, `init.FOO = true;` is translated to `[FOO:YES]` in init.txt
  29 , settings ? { }
  30 # TODO world-gen.txt, interface.txt require special logic
  31 }:
  32
  33 let
  34   dfhack_ = dfhack.override {
  35     inherit enableStoneSense;
  36   };
  37
  38   ptheme =
  39     if builtins.isString theme
  40     then builtins.getAttr theme themes
  41     else theme;
  42
  43   baseEnv = buildEnv {
  44     name = "dwarf-fortress-base-env-${dwarf-fortress.dfVersion}";
  45
  46     # These are in inverse order for first packages to override the next ones.
  47     paths = extraPackages
  48          ++ lib.optional (theme != null) ptheme
  49          ++ lib.optional enableDFHack dfhack_
  50          ++ lib.optional enableSoundSense soundSense
  51          ++ lib.optionals enableTWBT [ twbt.lib twbt.art ]
  52          ++ [ dwarf-fortress ];
  53
  54     ignoreCollisions = true;
  55   };
  56
  57   settings_ = lib.recursiveUpdate {
  58     init = {
  59       PRINT_MODE =
  60         if enableTextMode then "TEXT"
  61         else if enableTWBT then "TWBT"
  62         else if stdenv.hostPlatform.isDarwin then "STANDARD" # https://www.bay12games.com/dwarves/mantisbt/view.php?id=11680
  63         else null;
  64       INTRO = enableIntro;
  65       TRUETYPE = enableTruetype;
  66       FPS = enableFPS;
  67       SOUND = enableSound;
  68     };
  69   } settings;
  70
  71   forEach = attrs: f: lib.concatStrings (lib.mapAttrsToList f attrs);
  72
  73   toTxt = v:
  74     if lib.isBool v then if v then "YES" else "NO"
  75     else if lib.isInt v then toString v
  76     else if lib.isString v then v
  77     else throw "dwarf-fortress: unsupported configuration value ${toString v}";
  78
  79   config = runCommand "dwarf-fortress-config" {
  80     nativeBuildInputs = [ gawk ];
  81   } (''
  82     mkdir -p $out/data/init
  83
  84     edit_setting() {
  85       v=''${v//'&'/'\&'}
  86       if ! gawk -i inplace -v RS='\r?\n' '
  87         { n += sub("\\[" ENVIRON["k"] ":[^]]*\\]", "[" ENVIRON["k"] ":" ENVIRON["v"] "]"); print }
  88         END { exit(!n) }
  89       ' "$out/$file"; then
  90         echo "error: no setting named '$k' in $file" >&2
  91         exit 1
  92       fi
  93     }
  94   '' + forEach settings_ (file: kv: ''
  95     file=data/init/${lib.escapeShellArg file}.txt
  96     cp ${baseEnv}/"$file" "$out/$file"
  97   '' + forEach kv (k: v: lib.optionalString (v != null) ''
  98     export k=${lib.escapeShellArg k} v=${lib.escapeShellArg (toTxt v)}
  99     edit_setting
 100   '')) + lib.optionalString enableDFHack ''
 101     mkdir -p $out/hack
 102
 103     # Patch the MD5
 104     orig_md5=$(< "${dwarf-fortress}/hash.md5.orig")
 105     patched_md5=$(< "${dwarf-fortress}/hash.md5")
 106     input_file="${dfhack_}/hack/symbols.xml"
 107     output_file="$out/hack/symbols.xml"
 108
 109     echo "[DFHack Wrapper] Fixing Dwarf Fortress MD5:"
 110     echo "  Input:   $input_file"
 111     echo "  Search:  $orig_md5"
 112     echo "  Output:  $output_file"
 113     echo "  Replace: $patched_md5"
 114
 115     substitute "$input_file" "$output_file" --replace "$orig_md5" "$patched_md5"
 116   '');
 117
 118   # This is a separate environment because the config files to modify may come
 119   # from any of the paths in baseEnv.
 120   env = buildEnv {
 121     name = "dwarf-fortress-env-${dwarf-fortress.dfVersion}";
 122     paths = [ config baseEnv ];
 123     ignoreCollisions = true;
 124   };
 125 in
 126
 127 lib.throwIf (enableTWBT && !enableDFHack) "dwarf-fortress: TWBT requires DFHack to be enabled"
 128 lib.throwIf (enableStoneSense && !enableDFHack) "dwarf-fortress: StoneSense requires DFHack to be enabled"
 129 lib.throwIf (enableTextMode && enableTWBT) "dwarf-fortress: text mode and TWBT are mutually exclusive"
 130
 131 stdenv.mkDerivation {
 132   pname = "dwarf-fortress";
 133   version = dwarf-fortress.dfVersion;
 134
 135   dfInit = substituteAll {
 136     name = "dwarf-fortress-init";
 137     src = ./dwarf-fortress-init.in;
 138     inherit env;
 139     exe =
 140       if stdenv.isLinux then "libs/Dwarf_Fortress"
 141       else "dwarfort.exe";
 142     stdenv_shell = "${stdenv.shell}";
 143     cp = "${coreutils}/bin/cp";
 144     rm = "${coreutils}/bin/rm";
 145     ln = "${coreutils}/bin/ln";
 146     cat = "${coreutils}/bin/cat";
 147     mkdir = "${coreutils}/bin/mkdir";
 148   };
 149
 150   runDF = ./dwarf-fortress.in;
 151   runDFHack = ./dfhack.in;
 152   runSoundSense = ./soundSense.in;
 153
 154   passthru = {
 155     inherit dwarf-fortress dwarf-therapist twbt env;
 156     dfhack = dfhack_;
 157   };
 158
 159   buildCommand = ''
 160     mkdir -p $out/bin
 161
 162     substitute $runDF $out/bin/dwarf-fortress \
 163       --subst-var-by stdenv_shell ${stdenv.shell} \
 164       --subst-var dfInit
 165     chmod 755 $out/bin/dwarf-fortress
 166   '' + lib.optionalString enableDFHack ''
 167     substitute $runDFHack $out/bin/dfhack \
 168       --subst-var-by stdenv_shell ${stdenv.shell} \
 169       --subst-var dfInit
 170     chmod 755 $out/bin/dfhack
 171   '' + lib.optionalString enableSoundSense ''
 172     substitute $runSoundSense $out/bin/soundsense \
 173       --subst-var-by stdenv_shell ${stdenv.shell} \
 174       --subst-var-by jre ${jdk.jre} \
 175       --subst-var dfInit
 176     chmod 755 $out/bin/soundsense
 177   '';
 178
 179   preferLocalBuild = true;
 180
 181   inherit (dwarf-fortress) meta;
 182 }