pkgs/games/koboredux/default.nix

   1 { lib, stdenv
   2 , fetchFromGitHub
   3 , fetchpatch
   4 , requireFile
   5 , cmake
   6 , pkg-config
   7 , SDL2
   8 , SDL2_image
   9 , audiality2
  10 , useProprietaryAssets ? true
  11 }:
  12
  13 with lib;
  14
  15 let
  16   pname = "koboredux";
  17   version = "0.7.5.1";
  18
  19   main_src = fetchFromGitHub {
  20     owner = "olofson";
  21     repo = pname;
  22     rev = "v${version}";
  23     sha256 = "09h9r65z8bar2z89s09j6px0gdq355kjf38rmd85xb2aqwnm6xig";
  24   };
  25
  26   assets_src = requireFile {
  27     name = "koboredux-${version}-Linux.tar.bz2";
  28     sha256 = "11bmicx9i11m4c3dp19jsql0zy4rjf5a28x4hd2wl8h3bf8cdgav";
  29     message = ''
  30       Please purchase the game on https://olofson.itch.io/kobo-redux
  31       and download the Linux build.
  32
  33       Once you have downloaded the file, please use the following command
  34       and re-run the installation:
  35
  36       nix-prefetch-url file://\$PWD/koboredux-${version}-Linux.tar.bz2
  37
  38       Alternatively, install the "koboredux-free" package, which replaces the
  39       proprietary assets with a placeholder theme.
  40     '';
  41   };
  42
  43 in
  44
  45 stdenv.mkDerivation rec {
  46   inherit pname version;
  47
  48   src = [ main_src ] ++ optional useProprietaryAssets assets_src;
  49
  50   sourceRoot = main_src.name;
  51
  52   # Fix clang build
  53   patches = [(fetchpatch {
  54     url = "https://github.com/olofson/koboredux/commit/cf92b8a61d002ccaa9fbcda7a96dab08a681dee4.patch";
  55     sha256 = "0dwhvis7ghf3mgzjd2rwn8hk3ndlgfwwcqaq581yc5rwd73v6vw4";
  56   })];
  57
  58   postPatch = optionalString useProprietaryAssets ''
  59     cp -r ../koboredux-${version}-Linux/sfx/redux data/sfx/
  60     cp -r ../koboredux-${version}-Linux/gfx/redux data/gfx/
  61     cp -r ../koboredux-${version}-Linux/gfx/redux_fullscreen data/gfx/
  62   '';
  63
  64   nativeBuildInputs = [
  65     cmake
  66     pkg-config
  67   ];
  68
  69   buildInputs = [
  70     SDL2
  71     SDL2_image
  72     audiality2
  73   ];
  74
  75   meta = {
  76     description = "A frantic 80's style 2D shooter, similar to XKobo and Kobo Deluxe" +
  77       optionalString (!useProprietaryAssets) " (built without proprietary assets)";
  78     longDescription = ''
  79       Kobo Redux is a frantic 80's style 2D shooter, inspired by the look and
  80       feel of 90's arcade cabinets. The gameplay is fast and unforgiving,
  81       although with less of the frustrating quirkiness of the actual games
  82       of the 80's. A true challenge in the spirit of the arcade era!
  83     '' + optionalString (!useProprietaryAssets) ''
  84
  85       This version replaces the official proprietary assets with placeholders.
  86       For the full experience, consider installing "koboredux" instead.
  87     '';
  88     homepage = "https://olofson.itch.io/kobo-redux";
  89     license = with licenses; if useProprietaryAssets then unfree else gpl2;
  90     platforms = platforms.all;
  91     maintainers = with maintainers; [ fgaz ];
  92   };
  93 }
  94