pkgs/games/maptool/default.nix

   1 { lib
   2 , copyDesktopItems
   3 , fetchurl
   4 , ffmpeg
   5 , gitUpdater
   6 , jre
   7 , libarchive
   8 , makeDesktopItem
   9 , openjfx
  10 , stdenvNoCC
  11 , wrapGAppsHook
  12 }:
  13 let
  14   pname = "maptool";
  15   version = "1.13.2";
  16   repoBase = "https://github.com/RPTools/${pname}";
  17   src = fetchurl {
  18     url = "${repoBase}/releases/download/${version}/MapTool-${version}.jar";
  19     hash = "sha256-14ULI1OAk0V4DqiL5IF7DK6pw0NRfmU+omrFP72PblA=";
  20   };
  21
  22   icon = fetchurl {
  23     url = "https://raw.githubusercontent.com/RPTools/${pname}/${version}/package/linux/MapTool.png";
  24     hash = "sha256-xkVYjMprTanHu8r4b9PHORI8E1aJp+9KDSP5mqCE8ew=";
  25   };
  26
  27   meta = with lib; {
  28     description = "Virtual Tabletop for playing roleplaying games with remote players or face to face";
  29     homepage = "https://www.rptools.net/toolbox/maptool/";
  30     sourceProvenance = with sourceTypes; [
  31       binaryBytecode
  32       binaryNativeCode
  33     ];
  34     license = licenses.agpl3;
  35     maintainers = with maintainers; [ rhendric ];
  36   };
  37
  38   javafxModules = [ "base" "controls" "media" "swing" "web" "fxml" "graphics" ];
  39
  40   classpath =
  41     lib.concatMap (mod: [
  42       "${openjfx}/modules_src/javafx.${mod}/module-info.java"
  43       "${openjfx}/modules/javafx.${mod}"
  44       "${openjfx}/modules_libs/javafx.${mod}"
  45     ]) javafxModules ++
  46     [ src ];
  47
  48   jvmArgs = [
  49     "-cp" (lib.concatStringsSep ":" classpath)
  50     "-Xss8M"
  51     "-Dsun.java2d.d3d=false"
  52     "-Dfile.encoding=UTF-8"
  53     "-Dpolyglot.engine.WarnInterpreterOnly=false"
  54     "-XX:+ShowCodeDetailsInExceptionMessages"
  55     "--add-opens=java.desktop/java.awt=ALL-UNNAMED"
  56     "--add-opens=java.desktop/java.awt.geom=ALL-UNNAMED"
  57     "--add-opens=java.desktop/sun.awt.geom=ALL-UNNAMED"
  58     "--add-opens=java.base/java.util=ALL-UNNAMED"
  59     "--add-opens=javafx.web/javafx.scene.web=ALL-UNNAMED"
  60     "--add-opens=javafx.web/com.sun.webkit=ALL-UNNAMED"
  61     "--add-opens=javafx.web/com.sun.webkit.dom=ALL-UNNAMED"
  62     "--add-opens=java.desktop/javax.swing=ALL-UNNAMED"
  63     "--add-opens=java.desktop/sun.awt.shell=ALL-UNNAMED"
  64     "--add-opens=java.desktop/com.sun.java.swing.plaf.windows=ALL-UNNAMED"
  65
  66     # disable telemetry (the empty DSN disables the Sentry library, setting the
  67     # environment to Development disables some logic inside MapTool)
  68     "-Dsentry.dsn"
  69     "-Dsentry.environment=Development"
  70   ];
  71
  72   binName = pname;
  73   rdnsName = "net.rptools.maptool";
  74 in
  75 stdenvNoCC.mkDerivation {
  76   inherit pname version src meta;
  77
  78   dontUnpack = true;
  79   dontBuild = true;
  80   dontWrapGApps = true;
  81
  82   nativeBuildInputs = [
  83     copyDesktopItems
  84     libarchive
  85     wrapGAppsHook
  86   ];
  87
  88   desktopItems = [
  89     (makeDesktopItem {
  90       name = rdnsName;
  91       desktopName = "MapTool";
  92       icon = rdnsName;
  93       exec = binName;
  94       comment = meta.description;
  95       categories = [ "Game" ];
  96     })
  97   ];
  98
  99   installPhase = ''
 100     runHook preInstall
 101
 102     mkdir -p $out/bin
 103     makeWrapper ${jre}/bin/java $out/bin/${binName} \
 104       "''${gappsWrapperArgs[@]}" \
 105       --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ ffmpeg ]} \
 106       --add-flags '${lib.concatStringsSep " " jvmArgs} net.rptools.maptool.client.LaunchInstructions'
 107
 108     dest=$out/share/icons/hicolor/256x256/apps
 109     mkdir -p "$dest"
 110     ln -s ${icon} "$dest/${rdnsName}.png"
 111
 112     runHook postInstall
 113   '';
 114
 115   passthru.updateScript = gitUpdater {
 116     url = "${repoBase}.git";
 117     ignoredVersions = "-";
 118   };
 119 }