pkgs/games/osu-lazer/default.nix

   1 { lib
   2 , stdenvNoCC
   3 , buildDotnetModule
   4 , fetchFromGitHub
   5 , makeDesktopItem
   6 , copyDesktopItems
   7 , ffmpeg
   8 , alsa-lib
   9 , SDL2
  10 , lttng-ust
  11 , numactl
  12 , libglvnd
  13 , xorg
  14 , udev
  15 }:
  16
  17 buildDotnetModule rec {
  18   pname = "osu-lazer";
  19   version = "2023.1026.0";
  20
  21   src = fetchFromGitHub {
  22     owner = "ppy";
  23     repo = "osu";
  24     rev = version;
  25     sha256 = "sha256-kbi4Um1MRctpwD7ndlcB+K7AxDbWHqAHmkJbEI0fNzI=";
  26   };
  27
  28   projectFile = "osu.Desktop/osu.Desktop.csproj";
  29   nugetDeps = ./deps.nix;
  30
  31   nativeBuildInputs = [ copyDesktopItems ];
  32
  33   runtimeDeps = [
  34     ffmpeg
  35     alsa-lib
  36     SDL2
  37     lttng-ust
  38     numactl
  39
  40     # needed to avoid:
  41     # Failed to create SDL window. SDL Error: Could not initialize OpenGL / GLES library
  42     libglvnd
  43
  44     # needed for the window to actually appear
  45     xorg.libXi
  46
  47     # needed to avoid in runtime.log:
  48     # [verbose]: SDL error log [debug]: Failed loading udev_device_get_action: /nix/store/*-osu-lazer-*/lib/osu-lazer/runtimes/linux-x64/native/libSDL2.so: undefined symbol: _udev_device_get_action
  49     # [verbose]: SDL error log [debug]: Failed loading libudev.so.1: libudev.so.1: cannot open shared object file: No such file or directory
  50     udev
  51   ];
  52
  53   executables = [ "osu!" ];
  54
  55   fixupPhase = ''
  56     runHook preFixup
  57
  58     for i in 16 32 48 64 96 128 256 512 1024; do
  59       install -D ./assets/lazer.png $out/share/icons/hicolor/''${i}x$i/apps/osu\!.png
  60     done
  61
  62     ln -sft $out/lib/${pname} ${SDL2}/lib/libSDL2${stdenvNoCC.hostPlatform.extensions.sharedLibrary}
  63     cp -f ${./osu.runtimeconfig.json} "$out/lib/${pname}/osu!.runtimeconfig.json"
  64
  65     runHook postFixup
  66   '';
  67
  68   desktopItems = [(makeDesktopItem {
  69     desktopName = "osu!";
  70     name = "osu";
  71     exec = "osu!";
  72     icon = "osu!";
  73     comment = meta.description;
  74     type = "Application";
  75     categories = [ "Game" ];
  76   })];
  77
  78   meta = with lib; {
  79     description = "Rhythm is just a *click* away (no score submission or multiplayer, see osu-lazer-bin)";
  80     homepage = "https://osu.ppy.sh";
  81     license = with licenses; [
  82       mit
  83       cc-by-nc-40
  84       unfreeRedistributable # osu-framework contains libbass.so in repository
  85     ];
  86     maintainers = with maintainers; [ thiagokokada ];
  87     platforms = [ "x86_64-linux" ];
  88     mainProgram = "osu!";
  89   };
  90   passthru.updateScript = ./update.sh;
  91 }