pkgs/games/scummvm/default.nix

   1 { lib, stdenv, fetchFromGitHub, nasm
   2 , alsa-lib, curl, flac, fluidsynth, freetype, libjpeg, libmad, libmpeg2, libogg, libtheora, libvorbis, libGLU, libGL, SDL2, zlib
   3 , Cocoa, AudioToolbox, Carbon, CoreMIDI, AudioUnit, cctools
   4 }:
   5
   6 stdenv.mkDerivation rec {
   7   pname = "scummvm";
   8   version = "2.7.1";
   9
  10   src = fetchFromGitHub {
  11     owner = "scummvm";
  12     repo = "scummvm";
  13     rev = "v${version}";
  14     hash = "sha256-GVsvLAjb7pECd7uvPT9ubDFMIkiPWdU5owOafxk5iy0=";
  15   };
  16
  17   nativeBuildInputs = [ nasm ];
  18
  19   buildInputs = lib.optionals stdenv.isLinux [
  20     alsa-lib libGLU libGL
  21   ] ++ lib.optionals stdenv.isDarwin [
  22     Cocoa AudioToolbox Carbon CoreMIDI AudioUnit
  23   ] ++ [
  24     curl freetype flac fluidsynth libjpeg libmad libmpeg2 libogg libtheora libvorbis SDL2 zlib
  25   ];
  26
  27   dontDisableStatic = true;
  28
  29   enableParallelBuilding = true;
  30
  31   configurePlatforms = [ "host" ];
  32   configureFlags = [
  33     "--enable-release"
  34   ];
  35
  36   # They use 'install -s', that calls the native strip instead of the cross
  37   postConfigure = ''
  38     sed -i "s/-c -s/-c -s --strip-program=''${STRIP@Q}/" ports.mk
  39   '' + lib.optionalString stdenv.isDarwin ''
  40     substituteInPlace config.mk \
  41       --replace x86_64-apple-darwin-ranlib ${cctools}/bin/ranlib \
  42       --replace aarch64-apple-darwin-ranlib ${cctools}/bin/ranlib
  43   '';
  44
  45   meta = with lib; {
  46     description = "Program to run certain classic graphical point-and-click adventure games (such as Monkey Island)";
  47     homepage = "https://www.scummvm.org/";
  48     license = licenses.gpl2;
  49     maintainers = [ maintainers.peterhoeg ];
  50     platforms = platforms.unix;
  51   };
  52 }