pkgs/games/wipeout-rewrite/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , makeWrapper
   5 , Foundation
   6 , glew
   7 , SDL2
   8 , writeShellScript
   9 }:
  10
  11 let
  12   datadir = "\"\${XDG_DATA_HOME:-$HOME/.local/share}\"/wipeout-rewrite";
  13   datadirCheck = writeShellScript "wipeout-rewrite-check-datadir.sh" ''
  14     datadir=${datadir}
  15
  16     if [ ! -d "$datadir" ]; then
  17       echo "[Wrapper] Creating data directory $datadir"
  18       mkdir -p "$datadir"
  19     fi
  20
  21     echo "[Wrapper] Remember to put your game assets into $datadir/wipeout if you haven't done so yet!"
  22     echo "[Wrapper] Check https://github.com/phoboslab/wipeout-rewrite#running for the required format."
  23   '';
  24 in
  25 stdenv.mkDerivation (finalAttrs: {
  26   pname = "wipeout-rewrite";
  27   version = "unstable-2023-08-13";
  28
  29   src = fetchFromGitHub {
  30     owner = "phoboslab";
  31     repo = "wipeout-rewrite";
  32     rev = "7a9f757a79d5c6806252cc1268bda5cdef463e23";
  33     hash = "sha256-21IG9mZPGgRhVkT087G+Bz/zLkknkHKGmWjSpcLw8vE=";
  34   };
  35
  36   enableParallelBuilding = true;
  37
  38   nativeBuildInputs = [
  39     makeWrapper
  40   ];
  41
  42   buildInputs = [
  43     glew
  44     SDL2
  45   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  46     Foundation
  47   ];
  48
  49   installPhase = ''
  50     runHook preInstall
  51
  52     install -Dm755 wipegame $out/bin/wipegame
  53
  54     # I can't get --chdir to not expand the bash variables in datadir at build time (so they point to /homeless-shelter)
  55     # or put them inside single quotes (breaking the expansion at runtime)
  56     wrapProgram $out/bin/wipegame \
  57       --run '${datadirCheck}' \
  58       --run 'cd ${datadir}'
  59
  60     runHook postInstall
  61   '';
  62
  63   meta = with lib; {
  64     mainProgram = "wipegame";
  65     description = "A re-implementation of the 1995 PSX game wipEout";
  66     homepage = "https://github.com/phoboslab/wipeout-rewrite";
  67     license = licenses.unfree;
  68     maintainers = with maintainers; [ OPNA2608 ];
  69     platforms = platforms.all;
  70   };
  71 })