pkgs/misc/screensavers/multilockscreen/default.nix

   1 {
   2   lib, stdenv, makeWrapper, fetchFromGitHub, writeShellScriptBin,
   3   imagemagick, i3lock-color, xdpyinfo, xrandr, bc, feh, procps, xrdb, xset,
   4   gnused, gnugrep, coreutils
   5 }:
   6 let
   7   i3lock = writeShellScriptBin "i3lock" ''
   8     ${i3lock-color}/bin/i3lock-color "$@"
   9   '';
  10   binPath = lib.makeBinPath [
  11     imagemagick i3lock
  12     xdpyinfo xrandr xset
  13     bc feh procps xrdb
  14     gnused gnugrep coreutils
  15   ];
  16 in
  17 stdenv.mkDerivation rec {
  18   pname = "multilockscreen";
  19   version = "1.2.0";
  20
  21   src = fetchFromGitHub {
  22     owner = "jeffmhubbard";
  23     repo = pname;
  24     rev = "v${version}";
  25     sha256 = "1bfpbazvhaz9x356nsghz0czysh9b75g79cd9s35v0x0rrzdr9qj";
  26   };
  27
  28   nativeBuildInputs = [ makeWrapper ];
  29
  30   installPhase = ''
  31     mkdir -p $out/bin
  32     cp multilockscreen $out/bin/multilockscreen
  33     wrapProgram "$out/bin/multilockscreen" --prefix PATH : "${binPath}"
  34   '';
  35
  36   meta = with lib; {
  37     description = "Wrapper script for i3lock-color";
  38     longDescription = ''
  39       multilockscreen is a wrapper script for i3lock-color.
  40       It allows you to cache background images for i3lock-color with a variety of different effects and adds a stylish indicator.
  41     '';
  42     homepage = "https://github.com/jeffmhubbard/multilockscreen";
  43     license = licenses.mit;
  44     platforms = platforms.linux;
  45     maintainers = with maintainers; [ kylesferrazza ];
  46   };
  47 }