pkgs/top-level/emacs-packages.nix

   1 # package.el-based emacs packages
   2
   3 ## FOR USERS
   4 #
   5 # Recommended: simply use `emacsWithPackages` with the packages you want.
   6 #
   7 # Alternative: use `emacs`, install everything to a system or user profile
   8 # and then add this at the start your `early-init.el`:
   9 /*
  10   ;; optional. use this if you install emacs packages to the system profile
  11   (add-to-list 'package-directory-list "/run/current-system/sw/share/emacs/site-lisp/elpa")
  12
  13   ;; optional. use this if you install emacs packages to user profiles (with nix-env)
  14   (add-to-list 'package-directory-list "~/.nix-profile/share/emacs/site-lisp/elpa")
  15 */
  16
  17 { pkgs'
  18 , emacs'
  19 , makeScope
  20 , makeOverridable
  21 , dontRecurseIntoAttrs
  22 }:
  23
  24 let
  25
  26   mkElpaDevelPackages = { pkgs, lib }: import ../applications/editors/emacs/elisp-packages/elpa-devel-packages.nix {
  27     inherit (pkgs) stdenv texinfo writeText gcc pkgs buildPackages;
  28     inherit lib;
  29   };
  30
  31   mkElpaPackages = { pkgs, lib }: import ../applications/editors/emacs/elisp-packages/elpa-packages.nix {
  32     inherit (pkgs) stdenv texinfo writeText gcc pkgs buildPackages;
  33     inherit lib;
  34   };
  35
  36   mkNongnuPackages = { pkgs, lib }: import ../applications/editors/emacs/elisp-packages/nongnu-packages.nix {
  37     inherit (pkgs) buildPackages;
  38     inherit lib;
  39   };
  40
  41   # Contains both melpa stable & unstable
  42   melpaGeneric = { pkgs, lib }: import ../applications/editors/emacs/elisp-packages/melpa-packages.nix {
  43     inherit lib pkgs;
  44   };
  45
  46   mkManualPackages = { pkgs, lib }: import ../applications/editors/emacs/elisp-packages/manual-packages.nix {
  47     inherit lib pkgs;
  48   };
  49
  50   emacsWithPackages = { pkgs, lib }: pkgs.callPackage ../build-support/emacs/wrapper.nix {
  51     inherit (pkgs.xorg) lndir;
  52     inherit lib;
  53   };
  54
  55 in makeScope pkgs'.newScope (self: makeOverridable ({
  56   pkgs ? pkgs'
  57   , lib ? pkgs.lib
  58   , elpaDevelPackages ? mkElpaDevelPackages { inherit pkgs lib; } self
  59   , elpaPackages ? mkElpaPackages { inherit pkgs lib; } self
  60   , nongnuPackages ? mkNongnuPackages { inherit pkgs lib; } self
  61   , melpaStablePackages ? melpaGeneric { inherit pkgs lib; } "stable" self
  62   , melpaPackages ? melpaGeneric { inherit pkgs lib; } "unstable" self
  63   , manualPackages ? mkManualPackages { inherit pkgs lib; } self
  64 }: ({}
  65   // elpaDevelPackages // { inherit elpaDevelPackages; }
  66   // elpaPackages // { inherit elpaPackages; }
  67   // nongnuPackages // { inherit nongnuPackages; }
  68   // melpaStablePackages // { inherit melpaStablePackages; }
  69   // melpaPackages // { inherit melpaPackages; }
  70   // manualPackages // { inherit manualPackages; }
  71   // {
  72
  73     # Propagate overridden scope
  74     emacs = emacs'.overrideAttrs(old: {
  75       passthru = (old.passthru or {}) // {
  76         pkgs = dontRecurseIntoAttrs self;
  77       };
  78     });
  79
  80     trivialBuild = pkgs.callPackage ../build-support/emacs/trivial.nix {
  81       inherit (self) emacs;
  82     };
  83
  84     melpaBuild = pkgs.callPackage ../build-support/emacs/melpa.nix {
  85       inherit (self) emacs;
  86     };
  87
  88     emacsWithPackages = emacsWithPackages { inherit pkgs lib; } self;
  89     withPackages = emacsWithPackages { inherit pkgs lib; } self;
  90
  91   } // {
  92
  93     # Package specific priority overrides goes here
  94
  95     # EXWM is not tagged very often, prefer it from elpa devel.
  96     inherit (elpaDevelPackages) exwm;
  97
  98     # Telega uploads packages incompatible with stable tdlib to melpa
  99     # Prefer the one from melpa stable
 100     inherit (melpaStablePackages) telega;
 101
 102   })
 103 ) {})