pkgs/development/python-modules/ansible-kernel/default.nix

   1 { lib
   2 , buildPythonPackage
   3 , fetchPypi
   4 , writeText
   5 , ipywidgets
   6 , six
   7 , docopt
   8 , tqdm
   9 , jupyter
  10 , psutil
  11 , pyyaml
  12 , ansible-runner
  13 , ansible
  14 , python
  15 }:
  16
  17 let
  18   kernelSpecFile = writeText "kernel.json" (builtins.toJSON {
  19     argv = [ python.interpreter "-m" "ansible_kernel" "-f" "{connection_file}" ];
  20     codemirror_mode = "yaml";
  21     display_name = "Ansible";
  22     language = "ansible";
  23   });
  24 in
  25 buildPythonPackage rec {
  26   pname = "ansible-kernel";
  27   version = "1.0.0";
  28   format = "setuptools";
  29
  30   src = fetchPypi {
  31     inherit pname version;
  32     hash = "sha256-UJjm9FpmXSznXtaIR2rVv5YJS/H83FvRkNz09vwoe0c=";
  33   };
  34
  35   propagatedBuildInputs = [ ipywidgets six docopt tqdm jupyter psutil pyyaml ansible-runner ansible ];
  36
  37   postPatch = ''
  38    # remove when merged
  39    # https://github.com/ansible/ansible-jupyter-kernel/pull/82
  40    touch LICENSE.md
  41
  42    # remove custom install
  43    sed -i "s/cmdclass={'install': Installer},//" setup.py
  44   '';
  45
  46   # tests hang with launched kernel
  47   doCheck = false;
  48
  49   # install kernel manually
  50   postInstall = ''
  51     mkdir -p $out/share/jupyter/kernels/ansible/
  52     ln -s ${kernelSpecFile} $out/share/jupyter/kernels/ansible/kernel.json
  53   '';
  54
  55   meta = with lib; {
  56     description = "An Ansible kernel for Jupyter";
  57     homepage = "https://github.com/ansible/ansible-jupyter-kernel";
  58     license = licenses.asl20;
  59     maintainers = [ ];
  60   };
  61 }