pkgs/development/python-modules/flask-gravatar/default.nix

   1 { lib
   2 , buildPythonPackage
   3 , fetchPypi
   4 , fetchpatch
   5
   6 # build-system
   7 , setuptools
   8
   9 # dependencies
  10 , flask
  11
  12 # tests
  13 , pytestCheckHook
  14 , pygments
  15 }:
  16
  17 buildPythonPackage rec {
  18   pname = "flask-gravatar";
  19   version = "0.5.0";
  20   format = "setuptools";
  21
  22   src = fetchPypi {
  23     pname = "Flask-Gravatar";
  24     inherit version;
  25     sha256 = "YGZfMcLGEokdto/4Aek+06CIHGyOw0arxk0qmSP1YuE=";
  26   };
  27
  28   patches = [
  29     (fetchpatch {
  30       # flask 3.0 compat
  31       url = "https://github.com/zzzsochi/Flask-Gravatar/commit/d74d70d9695c464b602c96c2383d391b38ed51ac.patch";
  32       hash = "sha256-tCKkA2io/jhvrh6RhTeEw4AKnIZc9hsqTf2qItUsdjo=";
  33     })
  34   ];
  35
  36   postPatch = ''
  37     sed -i setup.py \
  38      -e "s|tests_require=tests_require,||g" \
  39      -e "s|extras_require=extras_require,||g" \
  40      -e "s|setup_requires=setup_requires,||g"
  41     # pep8 is deprecated and cov not needed
  42     substituteInPlace pytest.ini \
  43      --replace "--pep8" "" \
  44      --replace "--cov=flask_gravatar --cov-report=term-missing" ""
  45   '';
  46
  47   nativeBuildInputs = [
  48     setuptools
  49   ];
  50
  51   propagatedBuildInputs = [
  52     flask
  53   ];
  54
  55   nativeCheckInputs = [
  56     pytestCheckHook
  57     pygments
  58   ];
  59
  60   pythonImportsCheck = [
  61     "flask_gravatar"
  62   ];
  63
  64   meta = with lib; {
  65     homepage = "https://github.com/zzzsochi/Flask-Gravatar";
  66     description = "Small and simple integration of gravatar into flask";
  67     license = licenses.bsd3;
  68     maintainers = with maintainers; [ gador ];
  69   };
  70 }