pkgs/development/python-modules/grpcio/default.nix

   1 { lib
   2 , stdenv
   3 , buildPythonPackage
   4 , fetchPypi
   5 , grpc
   6 , six
   7 , protobuf
   8 , enum34 ? null
   9 , futures ? null
  10 , isPy27
  11 , pkg-config
  12 , cython
  13 , c-ares
  14 , openssl
  15 , zlib
  16 }:
  17
  18 buildPythonPackage rec {
  19   pname = "grpcio";
  20   format = "setuptools";
  21   version = "1.62.1";
  22
  23   src = fetchPypi {
  24     inherit pname version;
  25     hash = "sha256-bEVeAI+obZ6anYW7dtpCd8DX2WaKO/pw2+hunzx1mUc=";
  26   };
  27
  28   outputs = [ "out" "dev" ];
  29
  30   nativeBuildInputs = [ cython pkg-config ];
  31
  32   buildInputs = [ c-ares openssl zlib ];
  33   propagatedBuildInputs = [ six protobuf ]
  34     ++ lib.optionals (isPy27) [ enum34 futures ];
  35
  36   preBuild = ''
  37     export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$NIX_BUILD_CORES"
  38     if [ -z "$enableParallelBuilding" ]; then
  39       GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS=1
  40     fi
  41   '' + lib.optionalString stdenv.isDarwin ''
  42     unset AR
  43   '';
  44
  45   GRPC_BUILD_WITH_BORING_SSL_ASM = "";
  46   GRPC_PYTHON_BUILD_SYSTEM_OPENSSL = 1;
  47   GRPC_PYTHON_BUILD_SYSTEM_ZLIB = 1;
  48   GRPC_PYTHON_BUILD_SYSTEM_CARES = 1;
  49
  50   # does not contain any tests
  51   doCheck = false;
  52
  53   enableParallelBuilding = true;
  54
  55   pythonImportsCheck = [ "grpc" ];
  56
  57   meta = with lib; {
  58     description = "HTTP/2-based RPC framework";
  59     license = licenses.asl20;
  60     homepage = "https://grpc.io/grpc/python/";
  61     maintainers = with maintainers; [ ];
  62   };
  63 }