pkgs/development/python-modules/mxnet/default.nix

   1 { lib
   2 , buildPythonPackage
   3 , pkgs
   4 , requests
   5 , numpy
   6 , graphviz
   7 , python
   8 , isPy3k
   9 , isPy310
  10 }:
  11
  12 buildPythonPackage {
  13   inherit (pkgs.mxnet) pname version src;
  14
  15   format = "setuptools";
  16
  17   buildInputs = [ pkgs.mxnet ];
  18   propagatedBuildInputs = [ requests numpy graphviz ];
  19
  20   LD_LIBRARY_PATH = lib.makeLibraryPath [ pkgs.mxnet ];
  21
  22   doCheck = !isPy3k;
  23
  24   postPatch = ''
  25     # Required to support numpy >=1.24 where np.bool is removed in favor of just bool
  26     substituteInPlace python/mxnet/numpy/utils.py \
  27       --replace "bool = onp.bool" "bool = bool"
  28     substituteInPlace python/setup.py \
  29       --replace "graphviz<0.9.0," "graphviz"
  30   '';
  31
  32   preConfigure = ''
  33     cd python
  34   '';
  35
  36   postInstall = ''
  37     rm -rf $out/mxnet
  38     ln -s ${pkgs.mxnet}/lib/libmxnet.so $out/${python.sitePackages}/mxnet
  39   '';
  40
  41   meta = pkgs.mxnet.meta // {
  42     broken = (pkgs.mxnet.broken or false) || (isPy310 && pkgs.mxnet.cudaSupport);
  43   };
  44 }