pkgs/development/python-modules/wasmer/default.nix

   1 { stdenv
   2 , lib
   3 , rustPlatform
   4 , rustc
   5 , callPackage
   6 , fetchFromGitHub
   7 , buildPythonPackage
   8 , libiconv
   9 , libffi
  10 , libxml2
  11 , llvm_14
  12 , ncurses
  13 , zlib
  14 }:
  15
  16 let
  17   common =
  18     { pname
  19     , buildAndTestSubdir
  20     , cargoHash
  21     , extraNativeBuildInputs ? [ ]
  22     , extraBuildInputs ? [ ]
  23     }: buildPythonPackage rec {
  24       inherit pname;
  25       version = "1.1.0";
  26       format = "pyproject";
  27
  28       outputs = [ "out" ] ++ lib.optional (pname == "wasmer") "testsout";
  29
  30       src = fetchFromGitHub {
  31         owner = "wasmerio";
  32         repo = "wasmer-python";
  33         rev = version;
  34         hash = "sha256-nOeOhQ1XY+9qmLGURrI5xbgBUgWe5XRpV38f73kKX2s=";
  35       };
  36
  37       cargoDeps = rustPlatform.fetchCargoTarball {
  38         inherit src;
  39         name = "${pname}-${version}";
  40         sha256 = cargoHash;
  41       };
  42
  43       nativeBuildInputs = (with rustPlatform; [ cargoSetupHook maturinBuildHook ])
  44         ++ extraNativeBuildInputs;
  45
  46       postPatch = ''
  47         # Workaround for metadata, that maturin 0.14 does not accept in Cargo.toml anymore
  48         substituteInPlace ${buildAndTestSubdir}/Cargo.toml \
  49           --replace "package.metadata.maturin" "broken"
  50       '';
  51
  52       buildInputs = lib.optionals stdenv.isDarwin [ libiconv ]
  53         ++ extraBuildInputs;
  54
  55       inherit buildAndTestSubdir;
  56
  57       postInstall = lib.optionalString (pname == "wasmer") ''
  58         mkdir $testsout
  59         cp -R tests $testsout/tests
  60       '';
  61
  62       # check in passthru.tests.pytest because all packages are required to run the tests
  63       doCheck = false;
  64
  65       passthru.tests = lib.optionalAttrs (pname == "wasmer") {
  66         pytest = callPackage ./tests.nix { };
  67       };
  68
  69       pythonImportsCheck = [ "${lib.replaceStrings ["-"] ["_"] pname}" ];
  70
  71       meta = with lib; {
  72         description = "Python extension to run WebAssembly binaries";
  73         homepage = "https://github.com/wasmerio/wasmer-python";
  74         license = licenses.mit;
  75         platforms = platforms.unix;
  76         maintainers = [ ];
  77       };
  78     };
  79 in
  80 {
  81   wasmer = common {
  82     pname = "wasmer";
  83     buildAndTestSubdir = "packages/api";
  84     cargoHash = "sha256-twoog8LjQtoli+TlDipSuB7yLFkXQJha9BqobqgZW3Y=";
  85   };
  86
  87   wasmer-compiler-cranelift = common {
  88     pname = "wasmer-compiler-cranelift";
  89     buildAndTestSubdir = "packages/compiler-cranelift";
  90     cargoHash = "sha256-IqeMOY6emhIC7ekH8kIOZCr3JVkjxUg/lQli+ZZpdq4=";
  91   };
  92
  93   wasmer-compiler-llvm = common {
  94     pname = "wasmer-compiler-llvm";
  95     buildAndTestSubdir = "packages/compiler-llvm";
  96     cargoHash = "sha256-xawbf5gXXV+7I2F2fDSaMvjtFvGDBtqX7wL3c28TSbA=";
  97     extraNativeBuildInputs = [ llvm_14 ];
  98     extraBuildInputs = [ libffi libxml2.out ncurses zlib ];
  99   };
 100
 101   wasmer-compiler-singlepass = common {
 102     pname = "wasmer-compiler-singlepass";
 103     buildAndTestSubdir = "packages/compiler-singlepass";
 104     cargoHash = "sha256-4nZHMCNumNhdGPOmHXlJ5POYP7K+VPjwhEUMgzGb/Rk=";
 105   };
 106 }