pkgs/development/web/protege-distribution/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , unzip
   5 , jdk11
   6 , copyDesktopItems
   7 , iconConvTools
   8 , makeDesktopItem
   9 , makeWrapper
  10 }:
  11
  12 stdenv.mkDerivation rec {
  13   pname = "protege-distribution";
  14   version = "5.6.3";
  15
  16   src = fetchurl {
  17     url = "https://github.com/protegeproject/protege-distribution/releases/download/protege-${version}/Protege-${version}-platform-independent.zip";
  18     sha256 = "08pr0rn76wcc9bczdf93nlshxbid4z4nyvmaz198hhlq96aqpc3i";
  19   };
  20
  21   nativeBuildInputs = [
  22     copyDesktopItems
  23     iconConvTools
  24     jdk11
  25     makeWrapper
  26     unzip
  27   ];
  28
  29   patches = [
  30     # Replace logic for searching the install directory with a static cd into $out
  31     ./static-path.patch
  32     # Disable console logging, maintaining only file-based logging
  33     ./disable-console-log.patch
  34   ];
  35
  36   postPatch = ''
  37     # Resolve @out@ (introduced by "static-path.patch") to $out
  38     substituteInPlace run.sh --subst-var-by out $out
  39   '';
  40
  41   dontConfigure = true;
  42   dontBuild = true;
  43
  44   installPhase = ''
  45     runHook preInstall
  46
  47     mkdir -p $out/bin
  48
  49     # Wrap launch script to set $JAVA_HOME correctly
  50     mv run.sh $out/bin/run-protege
  51     wrapProgram  $out/bin/run-protege --set JAVA_HOME ${jdk11.home}
  52
  53     # Generate and copy icons to where they can be found
  54     icoFileToHiColorTheme app/Protege.ico protege $out
  55
  56     # Move everything else under protege/
  57     mkdir $out/protege
  58     mv {bundles,conf,plugins} $out/protege
  59
  60     runHook postInstall
  61   '';
  62
  63   desktopItems = [
  64     (makeDesktopItem {
  65       name = "Protege";
  66       desktopName = "Protege Desktop";
  67       icon = "protege";
  68       comment = "OWL2 ontology editor";
  69       categories = [ "Development" ];
  70       exec = "run-protege";
  71     })
  72   ];
  73
  74   meta = with lib; {
  75     description = "The OWL2 ontology editor from Stanford, with third-party plugins included";
  76     homepage = "https://protege.stanford.edu/";
  77     downloadPage = "https://protege.stanford.edu/products.php#desktop-protege";
  78     maintainers = with maintainers; [ nessdoor ];
  79     license = with licenses; [ asl20 bsd2 epl10 lgpl3 ];
  80     platforms = platforms.linux;
  81     mainProgram = "run-protege";
  82   };
  83 }