pkgs/development/compilers/julia/1.0.nix

   1 { lib, stdenv, fetchpatch, fetchurl, fetchzip
   2 # build tools
   3 , gfortran, m4, makeWrapper, patchelf, perl, which, python2
   4 , cmake
   5 # libjulia dependencies
   6 , libunwind, readline, utf8proc, zlib
   7 # standard library dependencies
   8 , curl, fftwSinglePrec, fftw, gmp, libgit2, mpfr, openlibm, openspecfun, pcre2
   9 # linear algebra
  10 , blas, lapack, arpack
  11 # Darwin frameworks
  12 , CoreServices, ApplicationServices
  13 }:
  14
  15
  16 let
  17   majorVersion = "1";
  18   minorVersion = "0";
  19   maintenanceVersion = "4";
  20   src_sha256 = "1dfx68wbrrzpbh74rla7i2g3r5z6wa1pxq3ahyfm5m27vfyjbkhg";
  21
  22   libuvVersion = "ed3700c849289ed01fe04273a7bf865340b2bd7e";
  23   libuvSha256 = "137w666zsjw1p0ma3lf94d75hr1q45sgkfmbizkyji2qm57cnxjs";
  24
  25   dsfmtVersion = "2.2.3";
  26   dsfmt = fetchurl {
  27     url = "http://www.math.sci.hiroshima-u.ac.jp/~m-mat/MT/SFMT/dSFMT-src-${dsfmtVersion}.tar.gz";
  28     sha256 = "03kaqbjbi6viz0n33dk5jlf6ayxqlsq4804n7kwkndiga9s4hd42";
  29   };
  30
  31   libuv = fetchurl {
  32     url = "https://api.github.com/repos/JuliaLang/libuv/tarball/${libuvVersion}";
  33     sha256 = libuvSha256;
  34   };
  35
  36   rmathVersion = "0.1";
  37   rmath-julia = fetchurl {
  38     url = "https://api.github.com/repos/JuliaLang/Rmath-julia/tarball/v${rmathVersion}";
  39     sha256 = "1qyps217175qhid46l8f5i1v8i82slgp23ia63x2hzxwfmx8617p";
  40   };
  41
  42   virtualenvVersion = "15.0.0";
  43   virtualenv = fetchurl {
  44     url = "mirror://pypi/v/virtualenv/virtualenv-${virtualenvVersion}.tar.gz";
  45     sha256 = "06fw4liazpx5vf3am45q2pdiwrv0id7ckv7n6zmpml29x6vkzmkh";
  46   };
  47
  48   libwhichVersion = "81e9723c0273d78493dc8c8ed570f68d9ce7e89e";
  49   libwhich = fetchurl {
  50     url = "https://api.github.com/repos/vtjnash/libwhich/tarball/${libwhichVersion}";
  51     sha256 = "1p7zg31kpmpbmh1znrk1xrbd074agx13b9q4dcw8n2zrwwdlbz3b";
  52   };
  53
  54   llvmVersion = "6.0.0";
  55   llvm = fetchurl {
  56     url = "http://releases.llvm.org/6.0.0/llvm-${llvmVersion}.src.tar.xz";
  57     sha256 = "0224xvfg6h40y5lrbnb9qaq3grmdc5rg00xq03s1wxjfbf8krx8z";
  58   };
  59
  60   suitesparseVersion = "4.4.5";
  61   suitesparse = fetchurl {
  62     url = "http://faculty.cse.tamu.edu/davis/SuiteSparse/SuiteSparse-${suitesparseVersion}.tar.gz";
  63     sha256 = "1jcbxb8jx5wlcixzf6n5dca2rcfx6mlcms1k2rl5gp67ay3bix43";
  64   };
  65   version = "${majorVersion}.${minorVersion}.${maintenanceVersion}";
  66 in
  67
  68 stdenv.mkDerivation rec {
  69   pname = "julia";
  70   inherit version;
  71
  72   src = fetchzip {
  73     url = "https://github.com/JuliaLang/${pname}/releases/download/v${version}/${pname}-${version}.tar.gz";
  74     sha256 = src_sha256;
  75   };
  76
  77   nativeBuildInputs = [ cmake curl gfortran m4 makeWrapper patchelf perl python2 which ];
  78   # cmake is only used to build the bundled deps
  79   dontUseCmakeConfigure = true;
  80
  81   # We assert that compatible blas and lapack are used.
  82   buildInputs = assert (blas.isILP64 == lapack.isILP64); [
  83     arpack fftw fftwSinglePrec gmp libgit2 libunwind mpfr
  84     pcre2.dev blas lapack openlibm openspecfun readline utf8proc
  85     zlib
  86   ]
  87   ++ lib.optionals stdenv.isDarwin [CoreServices ApplicationServices]
  88   ;
  89
  90   patches = [
  91     # Julia recompiles a precompiled file if the mtime stored *in* the
  92     # .ji file differs from the mtime of the .ji file.  This
  93     # doesn't work in Nix because Nix changes the mtime of files in
  94     # the Nix store to 1. So patch Julia to accept mtimes of 1.
  95     ./allow_nix_mtime.patch
  96     ./diagonal-test.patch
  97     ./use-system-utf8proc-julia-1.0.patch
  98   ];
  99
 100   postPatch = ''
 101     patchShebangs . contrib
 102     for i in backtrace cmdlineargs; do
 103       mv test/$i.jl{,.off}
 104       touch test/$i.jl
 105     done
 106     rm stdlib/Sockets/test/runtests.jl && touch stdlib/Sockets/test/runtests.jl
 107     rm stdlib/Distributed/test/runtests.jl && touch stdlib/Distributed/test/runtests.jl
 108     sed -e 's/Invalid Content-Type:/invalid Content-Type:/g' -i ./stdlib/LibGit2/test/libgit2.jl
 109     sed -e 's/Failed to resolve /failed to resolve /g' -i ./stdlib/LibGit2/test/libgit2.jl
 110   '';
 111   prePatch = ''
 112     mkdir deps/srccache
 113     cp "${dsfmt}" "./deps/srccache/dsfmt-${dsfmtVersion}.tar.gz"
 114     cp "${rmath-julia}" "./deps/srccache/Rmath-julia-${rmathVersion}.tar.gz"
 115     cp "${libuv}" "./deps/srccache/libuv-${libuvVersion}.tar.gz"
 116     cp "${virtualenv}" "./deps/srccache/virtualenv-${virtualenvVersion}.tar.gz"
 117     cp "${libwhich}" "./deps/srccache/libwhich-${libwhichVersion}.tar.gz"
 118     cp "${llvm}" "./deps/srccache/llvm-${llvmVersion}.src.tar.xz"
 119     cp "${suitesparse}" "./deps/srccache/SuiteSparse-${suitesparseVersion}.tar.gz"
 120   '';
 121
 122   makeFlags =
 123     let
 124       arch = lib.head (lib.splitString "-" stdenv.system);
 125       march = {
 126         x86_64 = stdenv.hostPlatform.gcc.arch or "x86-64";
 127         i686 = "pentium4";
 128         aarch64 = "armv8-a";
 129       }.${arch}
 130               or (throw "unsupported architecture: ${arch}");
 131       # Julia requires Pentium 4 (SSE2) or better
 132       cpuTarget = { x86_64 = "x86-64"; i686 = "pentium4"; aarch64 = "generic"; }.${arch}
 133                   or (throw "unsupported architecture: ${arch}");
 134     in [
 135       "ARCH=${arch}"
 136       "MARCH=${march}"
 137       "JULIA_CPU_TARGET=${cpuTarget}"
 138       "PREFIX=$(out)"
 139       "prefix=$(out)"
 140       "SHELL=${stdenv.shell}"
 141
 142       (lib.optionalString (!stdenv.isDarwin) "USE_SYSTEM_BLAS=1")
 143       "USE_BLAS64=${if blas.isILP64 then "1" else "0"}"
 144
 145       "USE_SYSTEM_LAPACK=1"
 146
 147       "USE_SYSTEM_ARPACK=1"
 148       "USE_SYSTEM_FFTW=1"
 149       "USE_SYSTEM_GMP=1"
 150       "USE_SYSTEM_LIBGIT2=1"
 151       "USE_SYSTEM_LIBUNWIND=1"
 152
 153       # We will probably never do that
 154       #"USE_SYSTEM_LLVM=1"
 155       "LLVM_VER=6.0.0"
 156
 157       "USE_SYSTEM_MPFR=1"
 158       "USE_SYSTEM_OPENLIBM=1"
 159       "USE_SYSTEM_OPENSPECFUN=1"
 160       "USE_SYSTEM_PATCHELF=1"
 161       "USE_SYSTEM_PCRE=1"
 162       "PCRE_CONFIG=${pcre2.dev}/bin/pcre2-config"
 163       "PCRE_INCL_PATH=${pcre2.dev}/include/pcre2.h"
 164       "USE_SYSTEM_READLINE=1"
 165       "USE_SYSTEM_UTF8PROC=1"
 166       "USE_SYSTEM_ZLIB=1"
 167     ];
 168
 169   LD_LIBRARY_PATH = assert (blas.isILP64 == lapack.isILP64); (lib.makeLibraryPath [
 170     arpack fftw fftwSinglePrec gmp libgit2 mpfr blas lapack openlibm
 171     openspecfun pcre2
 172   ]);
 173
 174   doCheck = !stdenv.isDarwin;
 175   checkTarget = "testall";
 176   # Julia's tests require read/write access to $HOME
 177   preCheck = ''
 178     export HOME="$NIX_BUILD_TOP"
 179   '';
 180
 181   preBuild = ''
 182     sed -e '/^install:/s@[^ ]*/doc/[^ ]*@@' -i Makefile
 183     sed -e '/[$](DESTDIR)[$](docdir)/d' -i Makefile
 184     export LD_LIBRARY_PATH=${LD_LIBRARY_PATH}
 185   '';
 186
 187   postInstall = ''
 188     # Symlink shared libraries from LD_LIBRARY_PATH into lib/julia,
 189     # as using a wrapper with LD_LIBRARY_PATH causes segmentation
 190     # faults when program returns an error:
 191     #   $ julia -e 'throw(Error())'
 192     find $(echo $LD_LIBRARY_PATH | sed 's|:| |g') -maxdepth 1 -name '*.${if stdenv.isDarwin then "dylib" else "so"}*' | while read lib; do
 193       if [[ ! -e $out/lib/julia/$(basename $lib) ]]; then
 194         ln -sv $lib $out/lib/julia/$(basename $lib)
 195       fi
 196     done
 197   '';
 198
 199   passthru = {
 200     inherit majorVersion minorVersion maintenanceVersion;
 201     site = "share/julia/site/v${majorVersion}.${minorVersion}";
 202   };
 203
 204   meta = {
 205     description = "High-level performance-oriented dynamical language for technical computing";
 206     homepage = "https://julialang.org/";
 207     license = lib.licenses.mit;
 208     maintainers = with lib.maintainers; [ raskin rob garrison ];
 209     platforms = [ "i686-linux" "x86_64-linux" "x86_64-darwin" "aarch64-linux" ];
 210   };
 211 }