pkgs/development/compilers/swi-prolog/default.nix

   1 { lib, stdenv, fetchFromGitHub, jdk, gmp, readline, openssl, unixODBC, zlib
   2 , libarchive, db, pcre, libedit, libossp_uuid, libXpm
   3 , libSM, libXt, freetype, pkg-config, fontconfig
   4 , cmake, libyaml, Security
   5 , libjpeg, libX11, libXext, libXft, libXinerama
   6 , extraLibraries ? [ jdk unixODBC libXpm libSM libXt freetype fontconfig ]
   7 # Packs must be installed from a local directory during the build, with dependencies
   8 # resolved manually, e.g. to install the 'julian' pack, which depends on the 'delay', 'list_util' and 'typedef' packs:
   9 #   julian = pkgs.fetchzip {
  10 #     name = "swipl-pack-julian";
  11 #     url = "https://github.com/mndrix/julian/archive/v0.1.3.zip";
  12 #     sha256 = "1sgql7c21p3c5m14kwa0bcmlwn9fql612krn9h36gla1j9yjdfgy";
  13 #   };
  14 #   delay = pkgs.fetchzip {
  15 #     name = "swipl-pack-delay";
  16 #     url = "https://github.com/mndrix/delay/archive/v0.3.3.zip";
  17 #     sha256 = "0ira87afxnc2dnbbmgwmrr8qvary8lhzvhqwd52dccm6yqd3nybg";
  18 #   };
  19 #   list_util = pkgs.fetchzip {
  20 #     name = "swipl-pack-list_util";
  21 #     url = "https://github.com/mndrix/list_util/archive/v0.13.0.zip";
  22 #     sha256 = "0lx7vffflak0y8l8vg8k0g8qddwwn23ksbz02hi3f8rbarh1n89q";
  23 #   };
  24 #   typedef = builtins.fetchTarball {
  25 #     name = "swipl-pack-typedef";
  26 #     url = "https://raw.githubusercontent.com/samer--/prolog/master/typedef/release/typedef-0.1.9.tgz";
  27 #     sha256 = "056nqjn01g18fb1b2qivv9s7hb4azk24nx2d4kvkbmm1k91f44p3";
  28 #   };
  29 #   swiProlog = pkgs.swiProlog.override { extraPacks = map (dep-path: "'file://${dep-path}'") [
  30 #     julian delay list_util typedef
  31 #   ]; };
  32 , extraPacks ? []
  33 , withGui ? false
  34 }:
  35
  36 let
  37   version = "8.3.9";
  38   packInstall = swiplPath: pack:
  39     ''${swiplPath}/bin/swipl -g "pack_install(${pack}, [package_directory(\"${swiplPath}/lib/swipl/pack\"), silent(true), interactive(false)])." -t "halt."
  40     '';
  41 in
  42 stdenv.mkDerivation {
  43   pname = "swi-prolog";
  44   inherit version;
  45
  46   src = fetchFromGitHub {
  47     owner = "SWI-Prolog";
  48     repo = "swipl-devel";
  49     rev = "V${version}";
  50     sha256 = "0ixb8pc5s7q8q0njs8is1clpvik6jhhdcwnys7m9rpwdzgi10sjz";
  51     fetchSubmodules = true;
  52   };
  53
  54   # Add the packInstall path to the swipl pack search path
  55   postPatch = ''
  56     echo "user:file_search_path(pack, '$out/lib/swipl/pack')." >> /build/$sourceRoot/boot/init.pl
  57   '';
  58
  59   nativeBuildInputs = [ cmake pkg-config ];
  60
  61   buildInputs = [ gmp readline openssl
  62     libarchive libyaml db pcre libedit libossp_uuid
  63     zlib ]
  64   ++ lib.optionals (withGui && !stdenv.isDarwin) [ libXpm libX11 libXext libXft libXinerama libjpeg ]
  65   ++ extraLibraries
  66   ++ lib.optional stdenv.isDarwin Security;
  67
  68   hardeningDisable = [ "format" ];
  69
  70   cmakeFlags = [ "-DSWIPL_INSTALL_IN_LIB=ON" ];
  71
  72   preInstall = ''
  73     mkdir -p $out/lib/swipl/pack
  74   '';
  75
  76   postInstall = builtins.concatStringsSep "\n"
  77   ( builtins.map (packInstall "$out") extraPacks
  78   );
  79
  80   meta = {
  81     homepage = "https://www.swi-prolog.org";
  82     description = "A Prolog compiler and interpreter";
  83     license = lib.licenses.bsd2;
  84
  85     platforms = lib.platforms.linux ++ lib.optionals (!withGui) lib.platforms.darwin;
  86     maintainers = [ lib.maintainers.meditans ];
  87   };
  88 }