pkgs/development/interpreters/love/0.8.nix

   1 { lib, stdenv, fetchurl, pkg-config
   2 , SDL, libGLU, libGL, openal, lua
   3 , libdevil, freetype, physfs
   4 , libmodplug, mpg123, libvorbis, libogg
   5 }:
   6
   7 stdenv.mkDerivation rec {
   8   pname = "love";
   9   version = "0.8.0";
  10
  11   src = fetchurl {
  12     url = "https://bitbucket.org/rude/love/downloads/${pname}-${version}-linux-src.tar.gz";
  13     sha256 = "1k4fcsa8zzi04ja179bmj24hvqcbm3icfvrvrzyz2gw9qwfclrwi";
  14   };
  15
  16   nativeBuildInputs = [ pkg-config ];
  17   buildInputs = [
  18     SDL libGLU libGL openal lua
  19     libdevil freetype physfs libmodplug mpg123 libvorbis libogg
  20   ];
  21
  22   preConfigure = ''
  23     luaoptions="${"''"} lua luajit "
  24     for i in lua luajit-; do
  25       for j in 5 5.0 5.1 5.2 5.3 5.4; do
  26         luaoptions="$luaoptions $i$j "
  27       done
  28     done
  29     luaso="$(echo "${lua}/lib/"lib*.so.*)"
  30     luaso="''${luaso##*/lib}"
  31     luaso="''${luaso%%.so*}"
  32     luaoptions="$luaoptions $luaso"
  33     sed -e "s/${"''"} lua lua.*;/$luaoptions;/" -i configure
  34
  35     luaincdir="$(echo "${lua}/include"/*/ )"
  36     test -d "$luaincdir" && {
  37       export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -I$luaincdir"
  38     } || true
  39   '';
  40
  41   NIX_CFLAGS_COMPILE = toString [
  42     "-I${SDL.dev}/include/SDL"
  43     "-I${freetype.dev}include/freetype2"
  44     "-DGL_GLEXT_PROTOTYPES" # https://community.khronos.org/t/glgenbuffers-was-not-declared-in-this-scope/59283/2
  45   ];
  46
  47   meta = {
  48     homepage = "http://love2d.org";
  49     description = "A Lua-based 2D game engine/scripting language";
  50     license = lib.licenses.zlib;
  51
  52     platforms = lib.platforms.linux;
  53     maintainers = [ lib.maintainers.raskin ];
  54   };
  55 }