pkgs/build-support/kernel/compress-firmware.nix

   1 { runCommand, lib, type ? "zstd", zstd }:
   2
   3 firmware:
   4
   5 let
   6   compressor = {
   7     xz = {
   8       ext = "xz";
   9       nativeBuildInputs = [ ];
  10       cmd = file: target: ''xz -9c -T1 -C crc32 --lzma2=dict=2MiB "${file}" > "${target}"'';
  11     };
  12     zstd = {
  13       ext = "zst";
  14       nativeBuildInputs = [ zstd ];
  15       cmd = file: target: ''zstd -T1 -19 --long --check -f "${file}" -o "${target}"'';
  16     };
  17   }.${type} or (throw "Unsupported compressor type for firmware.");
  18
  19   args = {
  20     allowedRequisites = [];
  21     inherit (compressor) nativeBuildInputs;
  22   } // lib.optionalAttrs (firmware ? meta) { inherit (firmware) meta; };
  23 in
  24
  25 runCommand "${firmware.name}-${type}" args ''
  26   mkdir -p $out/lib
  27   (cd ${firmware} && find lib/firmware -type d -print0) |
  28       (cd $out && xargs -0 mkdir -v --)
  29   (cd ${firmware} && find lib/firmware -type f -print0) |
  30       (cd $out && xargs -0rtP "$NIX_BUILD_CORES" -n1 \
  31           sh -c '${compressor.cmd "${firmware}/$1" "$1.${compressor.ext}"}' --)
  32   (cd ${firmware} && find lib/firmware -type l) | while read link; do
  33       target="$(readlink "${firmware}/$link")"
  34       if [ -f "${firmware}/$link" ]; then
  35         ln -vs -- "''${target/^${firmware}/$out}.${compressor.ext}" "$out/$link.${compressor.ext}"
  36       else
  37         ln -vs -- "''${target/^${firmware}/$out}" "$out/$link"
  38       fi
  39   done
  40
  41   echo "Checking for broken symlinks:"
  42   find -L $out -type l -print -execdir false -- '{}' '+'
  43 ''