pkgs/build-support/mitm-cache/fetch.nix

   1 { lib
   2 , fetchurl
   3 , runCommand
   4 , writeText
   5 }:
   6
   7 { name ? "deps"
   8 , data
   9 , dontFixup ? true
  10 , ...
  11 }
  12 @ attrs:
  13
  14 let
  15   data' = builtins.removeAttrs
  16     (if builtins.isPath data then lib.importJSON data else data)
  17     [ "!version" ];
  18
  19   urlToPath = url:
  20     if lib.hasPrefix "https://" url then (
  21       let
  22         url' = lib.drop 2 (lib.splitString "/" url);
  23       in "https/${builtins.concatStringsSep "/" url'}"
  24     )
  25     else builtins.replaceStrings ["://"] ["/"] url;
  26   code = ''
  27     mkdir -p "$out"
  28     cd "$out"
  29   '' + builtins.concatStringsSep "" (lib.mapAttrsToList (url: info:
  30   let
  31     key = builtins.head (builtins.attrNames info);
  32     val = info.${key};
  33     path = urlToPath url;
  34     name = baseNameOf path;
  35     source = {
  36       redirect = "$out/${urlToPath val}";
  37       hash = fetchurl { inherit url; hash = val; };
  38       text = writeText name val;
  39     }.${key} or (throw "Unknown key: ${url}");
  40   in ''
  41     mkdir -p "${dirOf path}"
  42     ln -s "${source}" "${path}"
  43   '') data');
  44 in
  45   runCommand name (builtins.removeAttrs attrs [ "name" "data" ] // {
  46     passthru = (attrs.passthru or {}) // {
  47       data = writeText "deps.json" (builtins.toJSON data);
  48     };
  49   }) code