pkgs/by-name/aw/aws-azure-login/package.nix

   1 { lib
   2 , callPackage
   3 , stdenv
   4 , chromium
   5 , fetchFromGitHub
   6 , fetchYarnDeps
   7 , makeWrapper
   8 , nodejs
   9 , fixup-yarn-lock
  10 , yarn
  11 }:
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "aws-azure-login";
  14   version = "3.6.1";
  15
  16   src = fetchFromGitHub {
  17     owner = "aws-azure-login";
  18     repo = "aws-azure-login";
  19     rev = "v${finalAttrs.version}";
  20     hash = "sha256-PvPnqaKD98h3dCjEOwF+Uc86xCJzn2b9XNHHn13h/2Y=";
  21   };
  22
  23   offlineCache = fetchYarnDeps {
  24     yarnLock = "${finalAttrs.src}/yarn.lock";
  25     hash = "sha256-SXQPRzF6b1FJl5HkyXNm3kGoNSDXux+0RYXBX93mOts=";
  26   };
  27
  28   nativeBuildInputs = [
  29     makeWrapper
  30     nodejs
  31     fixup-yarn-lock
  32     yarn
  33   ];
  34
  35   configurePhase = ''
  36     runHook preConfigure
  37
  38     export HOME=$(mktemp -d)
  39     yarn config --offline set yarn-offline-mirror "$offlineCache"
  40     fixup-yarn-lock yarn.lock
  41     yarn --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive install
  42     patchShebangs node_modules
  43
  44     runHook postConfigure
  45   '';
  46
  47   buildPhase = ''
  48     runHook preBuild
  49
  50     yarn --offline build
  51
  52     runHook postBuild
  53   '';
  54
  55   installPhase = ''
  56     runHook preInstall
  57
  58     yarn --offline --production install
  59
  60     mkdir -p "$out/lib/node_modules/aws-azure-login"
  61     cp -r . "$out/lib/node_modules/aws-azure-login"
  62
  63     makeWrapper "${nodejs}/bin/node" "$out/bin/aws-azure-login" \
  64       --add-flags "$out/lib/node_modules/aws-azure-login/lib/index.js" \
  65       --set PUPPETEER_EXECUTABLE_PATH "${lib.getExe chromium}"
  66
  67     runHook postInstall
  68   '';
  69
  70   passthru.tests.aws-azure-login = callPackage ./tests.nix {
  71     package = finalAttrs.finalPackage;
  72   };
  73
  74   meta = {
  75     description = "Use Azure AD SSO to log into the AWS via CLI";
  76     homepage = "https://github.com/aws-azure-login/aws-azure-login";
  77     license = lib.licenses.mit;
  78     mainProgram = "aws-azure-login";
  79     maintainers = with lib.maintainers; [ l0b0 ];
  80     platforms = lib.platforms.all;
  81   };
  82 })